Quelle  build.gradle.kts  Sprache: unbekannt

plugins {
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.android.multiplatform.library) apply false
    alias(libs.plugins.android.lint) apply false
    alias(libs.plugins.android.test) apply false
    alias(libs.plugins.compose) apply false
    alias(libs.plugins.kotlin.jvm) apply false
    alias(libs.plugins.kotlin.multiplatform) apply false
    alias(libs.plugins.kotlin.parcelize) apply false
    alias(libs.plugins.kotlin.serialization) apply false
    alias(libs.plugins.ksp) apply false
    alias(libs.plugins.jetbrains.compose) apply false
    alias(libs.plugins.buildconfig) apply false

    id("thunderbird.dependency.check")
    id("net.thunderbird.gradle.plugin.quality.coverage")
    id("net.thunderbird.gradle.plugin.quality.spotless")
    alias(libs.plugins.tb.featureflag.root)
}

featureFlag {
    val dir = project.layout.projectDirectory
    schema.set(dir.file("config/featureflag/thunderbird_mobile_featureflag.schema.json"))
    catalog.set(dir.file("config/featureflag/thunderbird_mobile_featureflag.catalog.json"))
}

tasks.withType<Test>().configureEach {
    testLogging {
        exceptionFormat = org.gradle.api.tasks.testing.logging.TestExceptionFormat.FULL
        showCauses = true
        showExceptions = true
        showStackTraces = true
    }
}

tasks.register("buildCliTools") {
    description = "Builds all CLI tools"
    // Keep this list up to date with the CLI tools in the project. This is used by the CI to build all CLI tools.
    dependsOn(
        ":cli:autodiscovery-cli:build",
        ":cli:html-cleaner-cli:build",
        ":cli:resource-mover-cli:build",
        ":cli:translation-cli:build",
        ":cli:weblate-cli:build",
    )
}

tasks.named<Wrapper>("wrapper") {
    gradleVersion = libs.versions.gradle.get()
    distributionType = Wrapper.DistributionType.ALL
    distributionSha256Sum = libs.versions.gradleSha256.get()
}

codeCoverage {
    branchCoverage = 26
    lineCoverage = 31
}