Quelle chap1.html Sprache: HTML

products/Sources/formale Sprachen/GAP/pkg/hap/tutorial/chap1.html

<?xml version="1.0" encoding="UTF-8"?>

<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN"
 "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">

<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en">
<head>
<title>GAP (HAP commands) - Chapter 1: Simplicial complexes & CW complexes</title>
<meta http-equiv="content-type" content="text/html; charset=UTF-8" />
<meta name="generator" content="GAPDoc2HTML" />
<link rel="stylesheet" type="text/css" href="manual.css" />
<script src="manual.js" type="text/javascript"></script>
<script type="text/javascript">overwriteStyle();</script>
</head>
<body class="chap1" onload="jscontent()">

<div class="chlinktop">Goto Chapter: <a href="chap0.html">Top</a> <a href="chap1.html">1</a> <a href="chap2.html">2</a> <a href="chap3.html">3</a> <a href="chap4.html">4</a> <a href="chap5.html">5</a> <a href="chap6.html">6</a> <a href="chap7.html">7</a> <a href="chap8.html">8</a> <a href="chap9.html">9</a> <a href="chap10.html">10</a> <a href="chap11.html">11</a> <a href="chap12.html">12</a> <a href="chap13.html">13</a> <a href="chap14.html">14</a> <a href="chap15.html">15</a> <a href="chap16.html">16</a> <a href="chapBib.html">Bib</a> <a href="chapInd.html">Ind</a> </div>

<div class="chlinkprevnexttop"> <a href="chap0.html">[Top of Book]</a> <a href="chap0.html#contents">[Contents]</a> <a href="chap0.html">[Previous Chapter]</a> <a href="chap2.html">[Next Chapter]</a> </div>

<a href="chap1_mj.html">[MathJax on]</a>
<a id="X7E5EA9587D4BCFB4" name="X7E5EA9587D4BCFB4"></a>
<div class="ChapSects"><a href="chap1.html#X7E5EA9587D4BCFB4">1 Simplicial complexes & CW complexes</a>
<div class="ContSect"> <a href="chap1.html#X85691C6980034524">1.1 The Klein bottle as a simplicial complex</a>

</div>
<div class="ContSect"> <a href="chap1.html#X7B8F88487B1B766C">1.2 Other simplicial surfaces</a>

</div>
<div class="ContSect"> <a href="chap1.html#X80A72C347D99A58E">1.3 The Quillen complex</a>

</div>
<div class="ContSect"> <a href="chap1.html#X7C4A2B8B79950232">1.4 The Quillen complex as a reduced CW-complex</a>

</div>
<div class="ContSect"> <a href="chap1.html#X782AAB84799E3C44">1.5 Simple homotopy equivalences</a>

</div>
<div class="ContSect"> <a href="chap1.html#X80474C7885AC1578">1.6 Cellular simplifications preserving homeomorphism type</a>

</div>
<div class="ContSect"> <a href="chap1.html#X7A15484C7E680AC9">1.7 Constructing a CW-structure on a knot complement</a>

</div>
<div class="ContSect"> <a href="chap1.html#X829793717FB6DDCE">1.8 Constructing a regular CW-complex by attaching cells</a>

</div>
<div class="ContSect"> <a href="chap1.html#X7B7354E68025FC92">1.9 Constructing a regular CW-complex from its face lattice</a>

</div>
<div class="ContSect"> <a href="chap1.html#X823FA6A9828FF473">1.10 Cup products</a>

</div>
<div class="ContSect"> <a href="chap1.html#X7F9B01CF7EE1D2FC">1.11 Intersection forms of 4-manifolds</a>

</div>
<div class="ContSect"> <a href="chap1.html#X80B6849C835B7F19">1.12 Cohomology Rings</a>

</div>
<div class="ContSect"> <a href="chap1.html#X83035DEC7C9659C6">1.13 Bockstein homomorphism</a>

</div>
<div class="ContSect"> <a href="chap1.html#X87135D067B6CDEEC">1.14 Diagonal maps on associahedra and other polytopes</a>

</div>
<div class="ContSect"> <a href="chap1.html#X8771FF2885105154">1.15 CW maps and induced homomorphisms</a>

</div>
<div class="ContSect"> <a href="chap1.html#X853D6B247D0E18DB">1.16 Constructing a simplicial complex from a regular CW-complex</a>

</div>
<div class="ContSect"> <a href="chap1.html#X7900FD197F175551">1.17 Some limitations to representing spaces as regular CW complexes</a>

</div>
<div class="ContSect"> <a href="chap1.html#X85A579217DCB6CC8">1.18 Equivariant CW complexes</a>

</div>
<div class="ContSect"> <a href="chap1.html#X86881717878ADCD6">1.19 Orbifolds and classifying spaces</a>

</div>
</div>

<h3>1 Simplicial complexes & CW complexes</h3>

<a id="X85691C6980034524" name="X85691C6980034524"></a>

<h4>1.1 The Klein bottle as a simplicial complex</h4>

<img src="images/klein.jpg" align="center" width="250" alt="Klein bottle"/> <img src="images/kleingrid.jpg" align="center" width="250"/ alt="simplicial Klein bottle"/>

The following example constructs the Klein bottle as a simplicial complex K on 9 vertices, and then constructs the cellular chain complex C_∗=C_∗(K) from which the integral homology groups H_1(K, Z)= Z_2⊕ Z, H_2(K, Z)=0 are computed. The chain complex D_∗=C_∗ ⊗_ Z Z_2 is also constructed and used to compute the mod-2 homology vector spaces H_1(K, Z_2)= Z_2⊕ Z_2, H_2(K, Z)= Z_2. Finally, a presentation π_1(K) = ⟨ x,y : yxy^-1x⟩ is computed for the fundamental group of K.

<div class="example"><pre>
gap> 2simplices:=
> [[1,2,5], [2,5,8], [2,3,8], [3,8,9], [1,3,9], [1,4,9],
> [4,5,8], [4,6,8], [6,8,9], [6,7,9], [4,7,9], [4,5,7],
> [1,4,6], [1,2,6], [2,6,7], [2,3,7], [3,5,7], [1,3,5]];;
gap> K:=SimplicialComplex(2simplices);
Simplicial complex of dimension 2.

gap> C:=ChainComplex(K);
Chain complex of length 2 in characteristic 0 .

gap> Homology(C,1);
[ 2, 0 ]
gap> Homology(C,2);
[ ]

gap> D:=TensorWithIntegersModP(C,2);
Chain complex of length 2 in characteristic 2 .

gap> Homology(D,1);
2
gap> Homology(D,2);
1

gap> G:=FundamentalGroup(K);
<fp group of size infinity on the generators [ f1, f2 ]>
gap> RelatorsOfFpGroup(G);
[ f2*f1*f2^-1*f1 ]

</pre></div>

<a id="X7B8F88487B1B766C" name="X7B8F88487B1B766C"></a>

<h4>1.2 Other simplicial surfaces</h4>

The following example constructs the real projective plane P, the Klein bottle K and the torus T as simplicial complexes, using the surface genus g as input in the oriented case and -g as input in the unoriented cases. It then confirms that the connected sums M=K#P and N=T#P have the same integral homology.

<div class="example"><pre>
gap> P:=ClosedSurface(-1);
Simplicial complex of dimension 2.

gap> K:=ClosedSurface(-2);
Simplicial complex of dimension 2.

gap> T:=ClosedSurface(1);
Simplicial complex of dimension 2.

gap> M:=ConnectedSum(K,P);
Simplicial complex of dimension 2.

gap> N:=ConnectedSum(T,P);
Simplicial complex of dimension 2.

gap> Homology(M,0);
[ 0 ]
gap> Homology(N,0);
[ 0 ]
gap> Homology(M,1);
[ 2, 0, 0 ]
gap> Homology(N,1);
[ 2, 0, 0 ]
gap> Homology(M,2);
[ ]
gap> Homology(N,2);
[ ]

</pre></div>

<a id="X80A72C347D99A58E" name="X80A72C347D99A58E"></a>

<h4>1.3 The Quillen complex</h4>

Given a group G one can consider the partially ordered set cal A_p(G) of all non-trivial elementary abelian p-subgroups of G, the partial order being set inclusion. The order complex ∆cal A_p(G) is a simplicial complex which is called the Quillen complex .

The following example constructs the Quillen complex ∆cal A_2(S_7) for the symmetric group of degree 7 and p=2. This simplicial complex involves 11291 simplices, of which 4410 are 2-simplices..

<div class="example"><pre>
gap> K:=QuillenComplex(SymmetricGroup(7),2);
Simplicial complex of dimension 2.

gap> Size(K);
11291

gap> K!.nrSimplices(2);
4410

</pre></div>

<a id="X7C4A2B8B79950232" name="X7C4A2B8B79950232"></a>

<h4>1.4 The Quillen complex as a reduced CW-complex</h4>

Any simplicial complex K can be regarded as a regular CW complex. Different datatypes are used in HAP for these two notions. The following continuation of the above Quillen complex example constructs a regular CW complex Y isomorphic to (i.e. with the same face lattice as) K=∆cal A_2(S_7). An advantage to working in the category of CW complexes is that it may be possible to find a CW complex X homotopy equivalent to Y but with fewer cells than Y. The cellular chain complex C_∗(X) of such a CW complex X is computed by the following commands. From the number of free generators of C_∗(X), which correspond to the cells of X, we see that there is a single 0-cell and 160 2-cells. Thus the Quillen complex $$\Delta{\cal A}_2(S_7) \simeq \bigvee_{1\le i\le 160} S^2$$ has the homotopy type of a wedge of 160 2-spheres. This homotopy equivalence is given in <a href="chapBib.html#biBksontini">[Kso00, (15.1)]</a> where it was obtained by purely theoretical methods.

<div class="example"><pre>
gap> Y:=RegularCWComplex(K);
Regular CW-complex of dimension 2

gap> C:=ChainComplex(Y);
Chain complex of length 2 in characteristic 0 .

gap> C!.dimension(0);
1
gap> C!.dimension(1);
0
gap> C!.dimension(2);
160

</pre></div>

<a id="X782AAB84799E3C44" name="X782AAB84799E3C44"></a>

<h4>1.5 Simple homotopy equivalences</h4>

For any regular CW complex Y one can look for a sequence of simple homotopy collapses Y↘ Y_1 ↘ Y_2 ↘ ... ↘ Y_N=X with X a smaller, and typically non-regular, CW complex. Such a sequence of collapses can be recorded using what is now known as a discrete vector field on Y. The sequence can, for example, be used to produce a chain homotopy equivalence f: C_∗ Y → C_∗ X and its chain homotopy inverse g: C_∗ X → C_∗ Y. The function <code class="code">ChainComplex(Y)</code> returns the cellular chain complex C_∗(X), wheras the function <code class="code">ChainComplexOfRegularCWComplex(Y)</code> returns the chain complex C_∗(Y).

For the above Quillen complex Y=∆cal A_2(S_7) the following commands produce the chain homotopy equivalence f: C_∗ Y → C_∗ X and g: C_∗ X → C_∗ Y. The number of generators of C_∗ Y equals the number of cells of Y in each degree, and this number is listed for each degree.

<div class="example"><pre>
gap> K:=QuillenComplex(SymmetricGroup(7),2);;
gap> Y:=RegularCWComplex(K);;
gap> CY:=ChainComplexOfRegularCWComplex(Y);
Chain complex of length 2 in characteristic 0 .

gap> CX:=ChainComplex(Y);
Chain complex of length 2 in characteristic 0 .

gap> equiv:=ChainComplexEquivalenceOfRegularCWComplex(Y);;
gap> f:=equiv[1];
Chain Map between complexes of length 2 .

gap> g:=equiv[2];
Chain Map between complexes of length 2 .

gap> CY!.dimension(0);
1316
gap> CY!.dimension(1);
5565
gap> CY!.dimension(2);
4410

</pre></div>

<a id="X80474C7885AC1578" name="X80474C7885AC1578"></a>

<h4>1.6 Cellular simplifications preserving homeomorphism type</h4>

For some purposes one might need to simplify the cell structure on a regular CW-complex Y so as to obtained a homeomorphic CW-complex W with fewer cells.

The following commands load a 4-dimensional simplicial complex Y representing the K3 complex surface. Its simplicial structure is taken from <a href="chapBib.html#biBspreerkhuenel">[SK11]</a> and involves 1704 cells of various dimensions. The commands then convert the cell structure into that of a homeomorphic regular CW-complex W involving 774 cells.

<div class="example"><pre>
gap> Y:=RegularCWComplex(SimplicialK3Surface());
Regular CW-complex of dimension 4

gap> Size(Y);
1704
gap> W:=SimplifiedComplex(Y);
Regular CW-complex of dimension 4

gap> Size(W);
774

</pre></div>

<a id="X7A15484C7E680AC9" name="X7A15484C7E680AC9"></a>

<h4>1.7 Constructing a CW-structure on a knot complement</h4>

The following commands construct the complement M=S^3∖ K of the trefoil knot K. This complement is returned as a 3-manifold M with regular CW-structure involving four 3-cells.

<div class="example"><pre>
gap> arc:=ArcPresentation(PureCubicalKnot(3,1));
[ [ 2, 5 ], [ 1, 3 ], [ 2, 4 ], [ 3, 5 ], [ 1, 4 ] ]
gap> S:=SphericalKnotComplement(arc);
Regular CW-complex of dimension 3

gap> S!.nrCells(3);
4

</pre></div>

The following additional commands then show that M is homotopy equivalent to a reduced CW-complex Y of dimension 2 involving one 0-cell, two 1-cells and one 2-cell. The fundamental group of Y is computed and used to calculate the Alexander polynomial of the trefoil knot.

<div class="example"><pre>
gap> Y:=ContractedComplex(S);
Regular CW-complex of dimension 2

gap> CriticalCells(Y);
[ [ 2, 1 ], [ 1, 9 ], [ 1, 11 ], [ 0, 22 ] ]
gap> G:=FundamentalGroup(Y);;
gap> AlexanderPolynomial(G);
x_1^2-x_1+1

</pre></div>

<a id="X829793717FB6DDCE" name="X829793717FB6DDCE"></a>

<h4>1.8 Constructing a regular CW-complex by attaching cells</h4>

<img src="images/cwspace2.jpg" align="center" width="250" alt="CW space"/>

The following example creates the projective plane Y as a regular CW-complex, and tests that it has the correct integral homology H_0(Y, Z)= Z, H_1(Y, Z)= Z_2, H_2(Y, Z)=0.

<div class="example"><pre>
gap> attch:=RegularCWComplex_AttachCellDestructive;; #Function for attaching cells

gap> Y:=RegularCWDiscreteSpace(3); #Discrete CW-complex consisting of points {1,2,3}
Regular CW-complex of dimension 0

gap> e1:=attch(Y,1,[1,2]);; #Attach 1-cell
gap> e2:=attch(Y,1,[1,2]);; #Attach 1-cell
gap> e3:=attch(Y,1,[1,3]);; #Attach 1-cell
gap> e4:=attch(Y,1,[1,3]);; #Attach 1-cell
gap> e5:=attch(Y,1,[2,3]);; #Attach 1-cell
gap> e6:=attch(Y,1,[2,3]);; #Attach 1-cell
gap> f1:=attch(Y,2,[e1,e3,e5]);; #Attach 2-cell
gap> f2:=attch(Y,2,[e2,e4,e5]);; #Attach 2-cell
gap> f3:=attch(Y,2,[e2,e3,e6]);; #Attach 2-cell
gap> f4:=attch(Y,2,[e1,e4,e6]);; #Attach 2-cell
gap> Homology(Y,0);
[ 0 ]
gap> Homology(Y,1);
[ 2 ]
gap> Homology(Y,2);
[ ]`

</pre></div>

The following example creates a 2-complex K corresponding to the group presentation

G=⟨ x,y,z : xyx^-1y^-1=1, yzy^-1z^-1=1, zxz^-1x^-1=1⟩.

The complex is shown to have the correct fundamental group and homology (since it is the 2-skeleton of the 3-torus S^1× S^1× S^1).

<div class="example"><pre>
gap> S1:=RegularCWSphere(1);;
gap> W:=WedgeSum(S1,S1,S1);;
gap> F:=FundamentalGroupWithPathReps(W);; x:=F.1;;y:=F.2;;z:=F.3;;
gap> K:=RegularCWComplexWithAttachedRelatorCells(W,F,Comm(x,y),Comm(y,z),Comm(x,z));
Regular CW-complex of dimension 2

gap> G:=FundamentalGroup(K);
<fp group on the generators [ f1, f2, f3 ]>
gap> RelatorsOfFpGroup(G);
[ f2^-1*f1*f2*f1^-1, f1^-1*f3*f1*f3^-1, f2^-1*f3*f2*f3^-1 ]
gap> Homology(K,1);
[ 0, 0, 0 ]
gap> Homology(K,2);
[ 0, 0, 0 ]

</pre></div>

<a id="X7B7354E68025FC92" name="X7B7354E68025FC92"></a>

<h4>1.9 Constructing a regular CW-complex from its face lattice</h4>

<img src="images/cwspace.jpg" align="center" width="250" alt="CW space"/>

The following example creats a 2-dimensional annulus A as a regular CW-complex, and testing that it has the correct integral homology H_0(A, Z)= Z, H_1(A, Z)= Z, H_2(A, Z)=0.

<div class="example"><pre>
gap> FL:=[];; #The face lattice
gap> FL[1]:=[[1,0],[1,0],[1,0],[1,0]];;
gap> FL[2]:=[[2,1,2],[2,3,4],[2,1,4],[2,2,3],[2,1,4],[2,2,3]];;
gap> FL[3]:=[[4,1,2,3,4],[4,1,2,5,6]];;
gap> FL[4]:=[];;
gap> A:=RegularCWComplex(FL);
Regular CW-complex of dimension 2

gap> Homology(A,0);
[ 0 ]
gap> Homology(A,1);
[ 0 ]
gap> Homology(A,2);
[ ]

</pre></div>

Next we construct the direct product Y=A× A× A× A× A of five copies of the annulus. This is a 10-dimensional CW complex involving 248832 cells. It will be homotopy equivalent Y≃ X to a CW complex X involving fewer cells. The CW complex X may be non-regular. We compute the cochain complex D_∗ = Hom_ Z(C_∗(X), Z) from which the cohomology groups H^0(Y, Z)= Z, H^1(Y, Z)= Z^5, H^2(Y, Z)= Z^10, H^3(Y, Z)= Z^10, H^4(Y, Z)= Z^5, H^5(Y, Z)= Z, H^6(Y, Z)=0 are obtained.

<div class="example"><pre>
gap> Y:=DirectProduct(A,A,A,A,A);
Regular CW-complex of dimension 10

gap> Size(Y);
248832
gap> C:=ChainComplex(Y);
Chain complex of length 10 in characteristic 0 .

gap> D:=HomToIntegers(C);
Cochain complex of length 10 in characteristic 0 .

gap> Cohomology(D,0);
[ 0 ]
gap> Cohomology(D,1);
[ 0, 0, 0, 0, 0 ]
gap> Cohomology(D,2);
[ 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ]
gap> Cohomology(D,3);
[ 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ]
gap> Cohomology(D,4);
[ 0, 0, 0, 0, 0 ]
gap> Cohomology(D,5);
[ 0 ]
gap> Cohomology(D,6);
[ ]

</pre></div>

<a id="X823FA6A9828FF473" name="X823FA6A9828FF473"></a>

<h4>1.10 Cup products</h4>

Strategy 1: Use geometric group theory in low dimensions.

Continuing with the previous example, we consider the first and fifth generators g_1^1, g_5^1∈ H^1(Y, Z) = Z^5 and establish that their cup product g_1^1 ∪ g_5^1 = - g_7^2 ∈ H^2(Y, Z) = Z^10 is equal to minus the seventh generator of H^2(Y, Z). We also verify that g_5^1∪ g_1^1 = - g_1^1 ∪ g_5^1.

<div class="example"><pre>
gap> cup11:=CupProduct(FundamentalGroup(Y));
function( a, b ) ... end

gap> cup11([1,0,0,0,0],[0,0,0,0,1]);
[ 0, 0, 0, 0, 0, 0, -1, 0, 0, 0 ]

gap> cup11([0,0,0,0,1],[1,0,0,0,0]);
[ 0, 0, 0, 0, 0, 0, 1, 0, 0, 0 ]

</pre></div>

This computation of low-dimensional cup products is achieved using group-theoretic methods to approximate the diagonal map ∆ : Y → Y× Y in dimensions ≤ 2. In order to construct cup products in higher degrees HAP invokes three further strategies.

Strategy 2: implement the Alexander-Whitney map for simplicial complexes.

For simplicial complexes the cup product is implemented using the standard formula for the Alexander-Whitney chain map, together with homotopy equivalences to improve efficiency.

As a first example, the following commands construct simplicial complexes K=( S^1 × S^1) # ( S^1 × S^1) and L=( S^1 × S^1) ∨ S^1 ∨ S^1 and establish that they have the same cohomology groups. It is then shown that the cup products ∪_K: H^2(K, Z)× H^2(K, Z) → H^4(K, Z) and ∪_L: H^2(L, Z)× H^2(L, Z) → H^4(L, Z) are antisymmetric bilinear forms of different ranks; hence K and L have different homotopy types.

<div class="example"><pre>
gap> K:=ClosedSurface(2);
Simplicial complex of dimension 2.

gap> L:=WedgeSum(WedgeSum(ClosedSurface(1),Sphere(1)),Sphere(1));
Simplicial complex of dimension 2.

gap> Cohomology(K,0);Cohomology(L,0);
[ 0 ]
[ 0 ]
gap> Cohomology(K,1);Cohomology(L,1);
[ 0, 0, 0, 0 ]
[ 0, 0, 0, 0 ]
gap> Cohomology(K,2);Cohomology(L,2);
[ 0 ]
[ 0 ]
gap> gens:=[[1,0,0,0],[0,1,0,0],[0,0,1,0],[0,0,0,1]];;
gap> cupK:=CupProduct(K);;
gap> cupL:=CupProduct(L);;
gap> A:=NullMat(4,4);;B:=NullMat(4,4);;
gap> for i in [1..4] do
> for j in [1..4] do
> A[i][j]:=cupK(1,1,gens[i],gens[j])[1];
> B[i][j]:=cupL(1,1,gens[i],gens[j])[1];
> od;od;
gap> Display(A);
[ [ 0, 0, 0, 1 ],
 [ 0, 0, 1, 0 ],
 [ 0, -1, 0, 0 ],
 [ -1, 0, 0, 0 ] ]
gap> Display(B);
[ [ 0, 1, 0, 0 ],
 [ -1, 0, 0, 0 ],
 [ 0, 0, 0, 0 ],
 [ 0, 0, 0, 0 ] ]
gap> Rank(A);
4
gap> Rank(B);
2

</pre></div>

As a second example of the computation of cups products, the following commands construct the connected sums V=M# M and W=M# overline M where M is the K3 complex surface which is stored as a pure simplicial complex of dimension 4 and where overline M denotes the opposite orientation on M. The simplicial structure on the K3 surface is taken from <a href="chapBib.html#biBspreerkhuenel">[SK11]</a>. The commands then show that H^2(V, Z)=H^2(W, Z)= Z^44 and H^4(V, Z)=H^4(W, Z)= Z. The final commands compute the matrix AV=(x∪ y) as x,y range over a generating set for H^2(V, Z) and the corresponding matrix AW for W. These two matrices are seen to have a different number of positive eigenvalues from which we can conclude that V is not homotopy equivalent to W.

<div class="example"><pre>
gap> M:=SimplicialK3Surface();;
gap> V:=ConnectedSum(M,M,+1);
Simplicial complex of dimension 4.

gap> W:=ConnectedSum(M,M,-1);
Simplicial complex of dimension 4.

gap> Cohomology(V,2);
[ 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0,
 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ]
gap> Cohomology(W,2);
[ 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0,
 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ]
gap> Cohomology(V,4);
[ 0 ]
gap> Cohomology(W,4);
[ 0 ]
gap> cupV:=CupProduct(V);;
gap> cupW:=CupProduct(W);;
gap> AV:=NullMat(44,44);; 
gap> AW:=NullMat(44,44);;
gap> gens:=IdentityMat(44);;
gap> for i in [1..44] do
> for j in [1..44] do
> AV[i][j]:=cupV(2,2,gens[i],gens[j])[1]; 
> AW[i][j]:=cupW(2,2,gens[i],gens[j])[1];
> od;od; 
gap> SignatureOfSymmetricMatrix(AV);
rec( determinant := 1, negative_eigenvalues := 22, positive_eigenvalues := 22,
 zero_eigenvalues := 0 )
gap> SignatureOfSymmetricMatrix(AW);
rec( determinant := 1, negative_eigenvalues := 6, positive_eigenvalues := 38,
 zero_eigenvalues := 0 )

</pre></div>

A cubical cubical version of the Alexander-Whitney formula, due to J.-P. Serre, could be used for computing the cohomology ring of a regular CW-complex whose cells all have a cubical combinatorial face lattice. This has not been implemented in HAP. However, the following more general approach has been implemented.

Strategy 3: Implement a cellular approximation to the diagonal map on an arbitrary finite regular CW-complex.

The following example calculates the cup product H^2(W, Z)× H^2(W, Z) → H^4(W, Z) for the 4-dimensional orientable manifold W=M× M where M is the closed surface of genus 2. The manifold W is stored as a regular CW-complex.

<div class="example"><pre>
gap> M:=RegularCWComplex(ClosedSurface(2));;
gap> W:=DirectProduct(M,M);
Regular CW-complex of dimension 4

gap> Size(W);
5776
gap> W:=SimplifiedComplex(W);;
gap> Size(W); 
1024

gap> Homology(W,2); 
[ 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ]
gap> Homology(W,4);
[ 0 ]

gap> cup:=CupProduct(W);;
gap> SecondCohomologtGens:=IdentityMat(18);; 
gap> A:=NullMat(18,18);;
gap> for i in [1..18] do
> for j in [1..18] do
> A[i][j]:=cup(2,2,SecondCohomologtGens[i],SecondCohomologtGens[j])[1];
> od;od;
gap> Display(A);
[ [ 0, -1, 0, 0, 0, 0, 3, -2, 0, 0, 0, 1, -1, 0, 0, 1, 0, 0 ],
 [ -1, -10, 1, 2, -2, 1, 6, -1, 0, -3, 4, -1, -1, -1, 4, -2, -2, 0 ],
 [ 0, 1, -2, 1, 0, -1, 0, 0, 1, 0, -1, 1, 0, 0, 1, -1, 0, 0 ],
 [ 0, 2, 1, -2, 1, 0, 0, -1, 0, 1, 0, 0, 0, 0, -1, 2, 0, 0 ],
 [ 0, -2, 0, 1, 0, 0, 1, -1, 0, 0, -1, 0, 0, 0, 0, -1, 0, 0 ],
 [ 0, 1, -1, 0, 0, 0, 0, 1, -1, 1, 0, 0, 0, 0, 1, -1, 0, 0 ],
 [ 3, 6, 0, 0, 1, 0, -4, 0, -1, 2, 4, -5, 2, -1, 1, 0, 3, 0 ],
 [ -2, -1, 0, -1, -1, 1, 0, 4, -2, 0, 0, 3, -1, 1, -1, 0, -2, 0 ],
 [ 0, 0, 1, 0, 0, -1, -1, -2, 4, -3, -10, 1, 0, 0, -3, 3, 0, 0 ],
 [ 0, -3, 0, 1, 0, 1, 2, 0, -3, 2, 3, 0, 0, 0, 1, -3, 0, 0 ],
 [ 0, 4, -1, 0, -1, 0, 4, 0, -10, 3, 18, 1, 0, 0, 0, 4, 0, 1 ],
 [ 1, -1, 1, 0, 0, 0, -5, 3, 1, 0, 1, 0, 0, 0, -2, -1, -1, 0 ],
 [ -1, -1, 0, 0, 0, 0, 2, -1, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0 ],
 [ 0, -1, 0, 0, 0, 0, -1, 1, 0, 0, 0, 0, 0, 0, 0, -1, -1, 0 ],
 [ 0, 4, 1, -1, 0, 1, 1, -1, -3, 1, 0, -2, 1, 0, 0, 2, 2, 0 ],
 [ 1, -2, -1, 2, -1, -1, 0, 0, 3, -3, 4, -1, 0, -1, 2, 0, 0, 0 ],
 [ 0, -2, 0, 0, 0, 0, 3, -2, 0, 0, 0, -1, 0, -1, 2, 0, 0, 0 ],
 [ 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0 ] ]

gap> SignatureOfSymmetricMatrix(A);
rec( determinant := -1, negative_eigenvalues := 9, positive_eigenvalues := 9,
 zero_eigenvalues := 0 )

</pre></div>

The matrix A representing the cup product H^2(W, Z)× H^2(W, Z) → H^4(W, Z) is shown to have 9 positive eigenvalues, 9 negative eigenvalues, and no zero eigenvalue.

Strategy 4: Guess and verify a cellular approximation to the diagonal map.

Many naturally occuring cell structures are neither simplicial nor cubical. For a general regular CW-complex we can attempt to construct a cellular inclusion overline Y ↪ Y× Y with {(y,y) : y∈ Y}⊂ overline Y and with projection p: overline Y ↠ Y that induces isomorphisms on integral homology. The function <code class="code">DiagonalApproximation(Y)</code> constructs a candidate inclusion, but the projection p: overline Y ↠ Y needs to be tested for homology equivalence. If the candidate inclusion passes this test then the function <code class="code">CupProductOfRegularCWComplex_alt(Y)</code>, involving the candidate space, can be used for cup products. (I think the test is passed for all regular CW-complexes that are subcomplexes of some Euclidean space with all cells convex polytopes -- but a proof needs to be written down!)

The following example calculates g_1^2 ∪ g_2^2 ne 0 where Y=T× T is the direct product of two copies of a simplicial torus T, and where g_k^n denotes the k-th generator in some basis of H^n(Y, Z). The direct product Y is a CW-complex which is not a simplicial complex.

<div class="example"><pre>
gap> K:=RegularCWComplex(ClosedSurface(1));;
gap> Y:=DirectProduct(K,K);;
gap> cup:=CupProductOfRegularCWComplex_alt(Y);;
gap> cup(2,2,[1,0,0,0,0,0],[0,1,0,0,0,0]);
[ 5 ]

gap> D:=DiagonalApproximation(Y);;
gap> p:=D!.projection;
Map of regular CW-complexes

gap> P:=ChainMap(p);
Chain Map between complexes of length 4 .

gap> IsIsomorphismOfAbelianFpGroups(Homology(P,0));
true
gap> IsIsomorphismOfAbelianFpGroups(Homology(P,2));
true
gap> IsIsomorphismOfAbelianFpGroups(Homology(P,3));
true
gap> IsIsomorphismOfAbelianFpGroups(Homology(P,4));
true

</pre></div>

Of course, either of Strategies 2 or 3 could also be used for this example. To use the Alexander-Whitney formula of Strategy 2 we would need to give the direct product Y=T× T a simplicial structure. This could be obtained using the function <code class="code">DirectProduct(T,T)</code>. The details are as follows. (The result is consistent with the preceding computation since the choice of a basis for cohomology groups is far from unique.)

<div class="example"><pre>
gap> K:=ClosedSurface(1);; 
gap> KK:=DirectProduct(K,K);
Simplicial complex of dimension 4.

gap> cup:=CupProduct(KK);; 
gap> cup(2,2,[1,0,0,0,0,0],[0,1,0,0,0,0]);
[ 0 ]

</pre></div>

<a id="X7F9B01CF7EE1D2FC" name="X7F9B01CF7EE1D2FC"></a>

<h4>1.11 Intersection forms of 4-manifolds</h4>

The cup product gives rise to the intersection form of a connected, closed, orientable 4-manifold Y is a symmetric bilinear form

qY: H^2(Y, Z)/Torsion × H^2(Y, Z)/Torsion ⟶ Z

which we represent as a symmetric matrix.

The following example constructs the direct product L=S^2× S^2 of two 2-spheres, the connected sum M= CP^2 # overline CP^2 of the complex projective plane CP^2 and its oppositely oriented version overline CP^2, and the connected sum N= CP^2 # CP^2. The manifolds L, M and N are each shown to have a CW-structure involving one 0-cell, two 1-cells and one 2-cell. They are thus simply connected and have identical cohomology.

<div class="example"><pre>
gap> S:=Sphere(2);;
gap> S:=RegularCWComplex(S);;
gap> L:=DirectProduct(S,S);
Regular CW-complex of dimension 4

gap> M:=ConnectedSum(ComplexProjectiveSpace(2),ComplexProjectiveSpace(2),-1);
Simplicial complex of dimension 4.

gap> N:=ConnectedSum(ComplexProjectiveSpace(2),ComplexProjectiveSpace(2),+1);
Simplicial complex of dimension 4.

gap> CriticalCells(L);
[ [ 4, 1 ], [ 2, 13 ], [ 2, 56 ], [ 0, 16 ] ]
gap> CriticalCells(RegularCWComplex(M));
[ [ 4, 1 ], [ 2, 109 ], [ 2, 119 ], [ 0, 8 ] ]
gap> CriticalCells(RegularCWComplex(N));
[ [ 4, 1 ], [ 2, 119 ], [ 2, 149 ], [ 0, 12 ] ]

</pre></div>

John Milnor showed (as a corollary to a theorem of J. H. C. Whitehead) that the homotopy type of a simply connected 4-manifold is determined by its quadratic form. More precisely, a form is said to be of type I (properly primitive) if some diagonal entry of its matrix is odd. If every diagonal entry is even, then the form is of type II (improperly primitive). The index of a form is defined as the number of positive diagonal entries minus the number of negative ones, after the matrix has been diagonalized over the real numbers.

Theorem. (Milnor <a href="chapBib.html#biBmilnor">[Mil58]</a>) The oriented homotopy type of a simply connected, closed, orientable 4-manifold is determined by its second Betti number and the index and type of its intersetion form; except possibly in the case of a manifold with definite quadratic form of rank r > 9.

The following commands compute matrices representing the intersection forms qL, qM, qN.

<div class="example"><pre>
gap> qL:=IntersectionForm(L);;
gap> qM:=IntersectionForm(M);;
gap> qN:=IntersectionForm(N);;
gap> Display(qL);
[ [ -2, 1 ],
 [ 1, 0 ] ]
gap> Display(qM);
[ [ 1, 0 ],
 [ 0, 1 ] ]
gap> Display(qN);
[ [ 1, 0 ],
 [ 0, -1 ] ]

</pre></div>

Since qL is of type II, whereas qM and qN are of type I we see that the oriented homotopy type of L is distinct to that of M and that of N. Since qM has index 2 and qN has index 0 we see that that M and N also have distinct oriented homotopy types.

<a id="X80B6849C835B7F19" name="X80B6849C835B7F19"></a>

<h4>1.12 Cohomology Rings</h4>

The cup product gives the cohomology H^∗(X,R) of a space X with coefficients in a ring R the structure of a graded commutitive ring. The function <code class="code">CohomologyRing(Y,p)</code> returns the cohomology as an algebra for Y a simplicial complex and R= Z_p the field of p elements. For more general regular CW-complexes or R= Z the cohomology ring structure can be determined using the function <code class="code">CupProduct(Y)</code>.

The folowing commands compute the mod 2 cohomology ring H^∗(W, Z_2) of the above wedge sum W=M∨ N of a 2-dimensional orientable simplicial surface of genus 2 and the K3 complex simplicial surface (of real dimension 4).

<div class="example"><pre>
gap> M:=ClosedSurface(2);;
gap> N:=SimplicialK3Surface();;
gap> W:=WedgeSum(M,N);;
gap> A:=CohomologyRing(W,2);
<algebra of dimension 29 over GF(2)>
gap> x:=Basis(A)[25];
v.25
gap> y:=Basis(A)[27];
v.27
gap> x*y;
v.29

</pre></div>

The functions <code class="code">CupProduct</code> and <code class="code">IntersectionForm</code> can be used to determine integral cohomology rings. For example, the integral cohomology ring of an arbitrary closed surface was calculated in <a href="chapBib.html#biBgoncalves">[GM15, Theorem 3.5]</a>. For any given surface M this result can be recalculated using the intersection form. For instance, for an orientable surface of genus g it is well-known that H^1(M, Z)= Z^2g, H^2(M, Z)= Z. The ring structure multiplication is thus given by the matrix of the intersection form. For say g=3 the ring multiplication is given, with respect to some cohomology basis, in the following.

<div class="example"><pre>
gap> M:=ClosedSurface(3);;
gap> Display(IntersectionForm(M));
[ [ 0, 0, 1, -1, -1, 0 ],
 [ 0, 0, 0, 1, 1, 0 ],
 [ -1, 0, 0, 1, 1, -1 ],
 [ 1, -1, -1, 0, 0, 1 ],
 [ 1, -1, -1, 0, 0, 0 ],
 [ 0, 0, 1, -1, 0, 0 ] ]

</pre></div>

By changing the basis B for H^1(M, Z) we obtain the following simpler matrix representing multiplication in H^∗(M, Z).

<div class="example"><pre>
gap> B:=[ [ 0, 1, -1, -1, 1, 0 ],
> [ 1, 0, 1, 1, 0, 0 ],
> [ 0, 0, 1, 0, 0, 0 ],
> [ 0, 0, 0, 1, -1, 0 ],
> [ 0, 0, 1, 1, 0, 0 ],
> [ 0, 0, 1, 1, 0, 1 ] ];;
gap> Display(IntersectionForm(M,B));
[ [ 0, 1, 0, 0, 0, 0 ],
 [ -1, 0, 0, 0, 0, 0 ],
 [ 0, 0, 0, 0, 1, 0 ],
 [ 0, 0, 0, 0, 0, 1 ],
 [ 0, 0, -1, 0, 0, 0 ],
 [ 0, 0, 0, -1, 0, 0 ] ]

</pre></div>

<a id="X83035DEC7C9659C6" name="X83035DEC7C9659C6"></a>

<h4>1.13 Bockstein homomorphism</h4>

The following example evaluates the Bockstein homomorphism β_2: H^∗(X, Z_2) → H^∗ +1(X, Z_2) on an additive basis for X=Σ^100( RP^2 × RP^2) the 100-fold suspension of the direct product of two projective planes.

<div class="example"><pre>
gap> P:=SimplifiedComplex(RegularCWComplex(ClosedSurface(-1)));
Regular CW-complex of dimension 2
gap> PP:=DirectProduct(P,P);;
gap> SPP:=Suspension(PP,100); 
Regular CW-complex of dimension 104
gap> A:=CohomologyRing(SPP,2); 
<algebra of dimension 9 over GF(2)>
gap> List(Basis(A),x->Bockstein(A,x));
[ 0*v.1, v.4, v.6, 0*v.1, v.7+v.8, 0*v.1, v.9, v.9, 0*v.1 ]

</pre></div>

If only the Bockstein homomorphism is required, and not the cohomology ring structure, then the Bockstein could also be computedirectly from a chain complex. The following computes the Bockstein β_2: H^2(Y, Z_2) → H^3(Y, Z_2) for the direct product Y=K × K × K × K of four copies of the Klein bottle represented as a regular CW-complex with 331776 cells. The order of the kernel and image of β_2 are computed.

<div class="example"><pre>
gap> K:=ClosedSurface(-2);; 
gap> K:=SimplifiedComplex(RegularCWComplex(K));;
gap> KKKK:=DirectProduct(K,K,K,K); 
Regular CW-complex of dimension 8
gap> Size(KKKK);
331776
gap> C:=ChainComplex(KKKK);;
gap> bk:=Bockstein(C,2,2);;
gap> Order(Kernel(bk));
1024
gap> Order(Image(bk)); 
262144

</pre></div>

<a id="X87135D067B6CDEEC" name="X87135D067B6CDEEC"></a>

<h4>1.14 Diagonal maps on associahedra and other polytopes</h4>

By a diagonal approximation on a regular CW-complex X we mean any cellular map ∆: X→ X× X that is homotopic to the diagonal map X→ X× X, x↦ (x,x) and equal to the diagonal map when restricted to the 0-skeleton. Theoretical formulae for diagonal maps on a polytope X can have interesting combinatorial aspects. To illustrate this let us consider, for n=3, the n-dimensional polytope cal K^n+2 known as the associahedron. The following commands display the 1-skeleton of cal K^5.

<div class="example"><pre>
gap> n:=3;;Y:=RegularCWAssociahedron(n+2);;
gap> Display(GraphOfRegularCWComplex(Y));

 </pre></div>

<img src="images/assoc.png" align="center" width="250" alt="Associahedron"/>

The induced chain map C_∗(cal K^n+2) → C_∗(cal K^n+2× cal K^n+2) sends the unique free generator e^n_1 of C_n(cal K^n+2) to a sum ∆(e^n_1) of a number of distinct free generators of C_n(cal K^n+2× cal K^n+2). Let |∆(e^n_1)| denote the number of free generators. For n=3 the following commands show that |∆(e^3_1)|=22 with each free generator occurring with coefficient ± 1.

<div class="example"><pre>
gap> n:=3;;Y:=RegularCWAssociahedron(n+2);; 
gap> D:=DiagonalChainMap(Y);;Filtered(D!.mapping([1],n),x->x<>0);
[ 1, 1, -1, -1, 1, 1, -1, -1, 1, -1, 1, 1, -1, 1, 1, 1, -1, -1, 1, 1, 1, 1 ]

 </pre></div>

Repeating this example for 0≤ n≤ 6 yields the sequence |∆(e^n_1)|: 1, 2, 6, 22, 91, 408, 1938, ⋯. The <a href="https://oeis.org/A000139">On-line Encyclopedia of Integer Sequences</a> explains that this is the beginning of the sequence given by the number of canopy intervals in the Tamari lattices.

Repeating the same experiment for the permutahedron, using the command <code class="code">RegularCWPermutahedron(n)</code>, yields the sequence |∆(e^n_1)|: 1, 2, 8, 50, 432, 4802,⋯. The <a href="https://oeis.org/A007334">On-line Encyclopedia of Integer Sequences</a> explains that this is the beginning of the sequence given by the number of spanning trees in the graph K_n/e, which results from contracting an edge e in the complete graph K_n on n vertices.

Repeating the experiment for the cube, using the command <code class="code">RegularCWCube(n)</code>, yields the sequence |∆(e^n_1)|: 1, 2, 4, 8, 16, 32,⋯.

Repeating the experiment for the simplex, using the command <code class="code">RegularCWSimplex(n)</code>, yields the sequence |∆(e^n_1)|: 1, 2, 3, 4, 5, 6,⋯.

<a id="X8771FF2885105154" name="X8771FF2885105154"></a>

<h4>1.15 CW maps and induced homomorphisms</h4>

A strictly cellular map f: X→ Y of regular CW-complexes is a cellular map for which the image of any cell is a cell (of possibly lower dimension). Inclusions of CW-subcomplexes, and projections from a direct product to a factor, are examples of such maps. Strictly cellular maps can be represented in HAP, and their induced homomorphisms on (co)homology and on fundamental groups can be computed.

The following example begins by visualizing the trefoil knot κ ∈ R^3. It then constructs a regular CW structure on the complement Y= D^3∖ Nbhd(κ) of a small tubular open neighbourhood of the knot lying inside a large closed ball D^3. The boundary of this tubular neighbourhood is a 2-dimensional CW-complex B homeomorphic to a torus S^1× S^1 with fundamental group π_1(B)=<a,b : aba^-1b^-1=1>. The inclusion map f: B↪ Y is constructed. Then a presentation π_1(Y)= <x,y | xy^-1x^-1yx^-1y^-1> and the induced homomorphism $$\pi_1(B)\rightarrow \pi_1(Y), a\mapsto y^{-1}xy^2xy^{-1}, b\mapsto y $$ are computed. This induced homomorphism is an example of a peripheral system and is known to contain sufficient information to characterize the knot up to ambient isotopy.

Finally, it is verified that the induced homology homomorphism H_2(B, Z) → H_2(Y, Z) is an isomomorphism.

<div class="example"><pre>
gap> K:=PureCubicalKnot(3,1);;
gap> ViewPureCubicalKnot(K);;

</pre></div>

<img src="images/trefoil.png" align="center" width="150" alt="trefoil knot"/>

<div class="example"><pre>
gap> K:=PureCubicalKnot(3,1);;
gap> f:=KnotComplementWithBoundary(ArcPresentation(K));
Map of regular CW-complexes

gap> G:=FundamentalGroup(Target(f));
<fp group of size infinity on the generators [ f1, f2 ]>
gap> RelatorsOfFpGroup(G);
[ f1*f2^-1*f1^-1*f2*f1^-1*f2^-1 ]

gap> F:=FundamentalGroup(f);
[ f1, f2 ] -> [ f2^-1*f1*f2^2*f1*f2^-1, f1 ]

gap> phi:=ChainMap(f);
Chain Map between complexes of length 2 .

gap> H:=Homology(phi,2);
[ g1 ] -> [ g1 ]

</pre></div>

<a id="X853D6B247D0E18DB" name="X853D6B247D0E18DB"></a>

<h4>1.16 Constructing a simplicial complex from a regular CW-complex</h4>

The following example constructs a 3-dimensional pure regular CW-complex K whose 3-cells are permutahedra. It then constructs the simplicial complex B by taking barycentric subdivision. It then constructes a smaller, homotopy equivalent, simplicial complex N by taking the nerve of the cover of K by the closures of its 3-cells.

<div class="example"><pre>
gap> K:=RegularCWComplex(PureComplexComplement(PurePermutahedralKnot(3,1)));
Regular CW-complex of dimension 3

gap> Size(K);
77923
gap> B:=BarycentricSubdivision(K);
Simplicial complex of dimension 3.

gap> Size(B);
1622517
gap> N:=Nerve(K);
Simplicial complex of dimension 3.

gap> Size(N);
48745

</pre></div>

<a id="X7900FD197F175551" name="X7900FD197F175551"></a>

<h4>1.17 Some limitations to representing spaces as regular CW complexes</h4>

--> --------------------

--> maximum size reached

--> --------------------

quality95%

¤ Dauer der Verarbeitung: 0.30 Sekunden (vorverarbeitet) ¤

Wurzel

Suchen

Beweissystem der NASA

Beweissystem Isabelle

NIST Cobol Testsuite

Cephes Mathematical Library

Wiener Entwicklungsmethode

Haftungshinweis

Die Informationen auf dieser Webseite wurden nach bestem Wissen sorgfältig zusammengestellt. Es wird jedoch weder Vollständigkeit, noch Richtigkeit, noch Qualität der bereit gestellten Informationen zugesichert.

Bemerkung:

Die farbliche Syntaxdarstellung ist noch experimentell.