Quelle  Com.thy   Sprache: Isabelle

chapter ‹Instantiating the Framework with a simple While-Language using procedures›

section ‹Commands›

theory Com imports "../StaticInter/BasicDefs" begin

subsection ‹Variables and Values›

type_synonym vname = string ― ‹names for variables›
type_synonym pname = string ― ‹names for procedures›

datatype val
  = Bool bool      ― ‹Boolean value›
  | Intg int       ― ‹integer value›

abbreviation "true == Bool True"
abbreviation "false == Bool False"


subsection ‹Expressions›

datatype bop = Eq | And | Less | Add | Sub     ― ‹names of binary operations›

datatype expr
  = Val val                                          ― ‹value›
  | Var vname                                        ― ‹local variable›
  | BinOp expr bop expr    (‹_ «_¬ _› [80,0,81] 80)  ― ‹binary operation›


fun binop :: "bop → val → val → val option"
where "binop Eq v₁ v₂ = Some(Bool(v₁ = v₂))"
  | "binop And (Bool b₁) (Bool b₂) = Some(Bool(b₁ ∧ b₂))"
  | "binop Less (Intg i₁) (Intg i₂) = Some(Bool(i₁ < i₂))"
  | "binop Add (Intg i₁) (Intg i₂) = Some(Intg(i₁ + i₂))"
  | "binop Sub (Intg i₁) (Intg i₂) = Some(Intg(i₁ - i₂))"
  | "binop bop v₁ v₂ = None"


subsection ‹Commands›

datatype cmd
  = Skip
  | LAss vname expr        (‹_:=_› [70,70] 70)  ― ‹local assignment›
  | Seq cmd cmd            (‹_;;/ _› [60,61] 60)
  | Cond expr cmd cmd      (‹if '(_') _/ else _› [80,79,79] 70)
  | While expr cmd         (‹while '(_') _› [80,79] 70)
  | Call pname "expr list" "vname list" 
    ― ‹Call needs procedure, actual parameters and variables for return values›



fun num_inner_nodes :: "cmd → nat" (‹#:_›)
where "#:Skip = 1"
  | "#:(V:=e) = 2"       (* additional Skip node *)
  | "#:(c₁;;c₂) = #:c₁ + #:c₂"
  | "#:(if (b) c₁ else c₂) = #:c₁ + #:c₂ + 1"
  | "#:(while (b) c) = #:c + 2" (* additional Skip node *)
  | "#:(Call p es rets) = 2"       (* additional Skip (=Return) node *)


lemma num_inner_nodes_gr_0 [simp]:"#:c > 0"
by(induct c) auto

lemma [dest]:"#:c = 0 ==> False"
by(induct c) auto


end