Quellcode-Bibliothek TRACE.REXX Sprache: REXX

/* REXX  */
/*                                                            */
/* Erzeugen von Testbefehlen in einem COBOL-Programm mit      */
/* Hilfe des COBOL-Programes KB243                            */
/*                                                            */
/* Aufruf aus dem Editor mit:                                 */
/*                                                            */
/*   TRACE                   zum Einscahlten der Displays     */
/*   TRACE off               zum Ausschalten der Displays     */
/*                                                            */
/* ---------------------------------------------------------- */

/* trace all */
   Version     = "Version 0.80 vom 8.01.2003"
   Autor       = "JD"
   Redakteur01 = ""


   /*-----------------------*/
   /* Parameter untersuchen */
   /*-----------------------*/
   arg parm1
   address isredit
   'ISREDIT MACRO (parm1) NOPROCESS'
   if parm1 = "" then
      arg parm1
   parm1 = translate(parm1)
   if parm1 = '?' then do
      call help
      exit
   end
   if parm1 = "OFF" ! parm1 = "off" then
      troff = 1
   else if parm1 = "" ! parm1 = "ON" ! parm1 = "on" then
      troff = 0
   else
      call help

   /*------------------------------------*/
   /* Ermitteln von DSN und Membername:  */
   /*------------------------------------*/
   'isredit (dsn) = dataset'
   rc_dsn = rc
   'isredit (mem) = member'
   rc_mem = rc
   fulldsn=dsn'('mem')'
   sys007   =''''userid()'.trace.sys007'''
   sys010   =''''fulldsn''''
   sys050   =''''userid()'.trace.sys050'''


   address isredit "save"

   address tso
   rc_list = listdsi(sys007)
   if rc_list /= 0 then do
      /* allocate new dataset */
      'ALLOC DA('sys007') NEW CATALOG SPACE(1,1)',
      'BLKSIZE(800) LRECL(80)'
   end

   rc_list = listdsi(sys050)
   if rc_list /= 0 then do
      /* allocate new dataset */
      'ALLOC DS('sys050') NEW CAT',
         'UNIT(DISK) SPACE(1 1) TRACKS',
         'RECFM(F B) LRECL(80) BLKSIZE(8000)'
   end


   /*-----------------------*/
   /* sys007 schreiben      */
   /*-----------------------*/
   'NEWSTACK'             /* get a new stack */
   rec =         ' '
   r   = date('E')
   r   = substr(r,1,2)'.'substr(r,4,2)'.'substr(r,7,2)
   rec = r !! rec
   rec = rec !! ' TAVK'
   queue rec
   if troff = 0 then
     c = 'A '
   else
     c = 'B '
   c   = c   !! ' KB243PS'
   queue c
   queue ''
   'FREE F(OUT)'
   'ALLOC F(OUT) DA('sys007') OLD'
   'EXECIO * DISKW OUT (FINIS'
   'FREE F(OUT)'
   'DELSTACK'                        /* delete stack */

   /*-----------------------*/
   /* Parameter untersuchen */
   /*-----------------------*/
   'free fi(sys007)'
   'free fi(sys010)'
   'free fi(sys050)'
   'alloc fi(sys007) da('sys007') SHR'
   'alloc fi(sys010) da('sys010') SHR'
   'alloc fi(sys050) da('sys050') SHR'
   'call ''db3b.anw.runlib.load(kb243)'''
   'free fi(sys007)'
   'free fi(sys010)'
   'free fi(sys050)'

   /*-----------------------*/
   /* exchange files        */
   /*-----------------------*/
   'NEWSTACK'
   'ALLOC F(IN) DA('sys050') SHR'
   'EXECIO * DISKR IN (FINIS'       /* READ  FILE TO STACK  */
    queue ''
   'FREE F(IN)'
   'ALLOC F(OUT) DA('sys010') SHR'
   'EXECIO * DISKW OUT (FINIS'      /* WRITE STACK TO THE FILE */
   'FREE F(OUT)'
   'DELSTACK'

   address isredit "end"

   /* address "ISPEXEC" edit "DATASET("sys010")" */

RETURN

HELP:
say ' '
say 'ISPF/PDF edit macro to assist debugging of COBOL-Progams '
say 'by insertion of DISPLAYs in each Section/Paragraph '
say ' '
say 'To turn on: '
say ' Enter "TRACE" in the command line '
say ' '
say 'To turn off: '
say ' Enter "TRACE OFF" in the comand line '
say ' '
say ' If you have questions about this command, '
say ' contact Hamburg -4244. '
Return

quality87%

¤ Die Informationen auf dieser Webseite wurden nach bestem Wissen sorgfältig zusammengestellt. Es wird jedoch weder Vollständigkeit, noch Richtigkeit, noch Qualität der bereit gestellten Informationen zugesichert.0.11Bemerkung: (vorverarbeitet) ¤

*Bot Zugriff

Wurzel

Suchen

Beweissystem der NASA

Beweissystem Isabelle

NIST Cobol Testsuite

Cephes Mathematical Library

Wiener Entwicklungsmethode

Haftungshinweis

Die Informationen auf dieser Webseite wurden nach bestem Wissen sorgfältig zusammengestellt. Es wird jedoch weder Vollständigkeit, noch Richtigkeit, noch Qualität der bereit gestellten Informationen zugesichert.

Bemerkung:

Die farbliche Syntaxdarstellung ist noch experimentell.