# Copyright 2013 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//chromium/build/util/lastchange.gni")

action("chromium_git_revision") {
  script = "version.py"

  template_file = "chromium_git_revision.h.in"
  inputs = [ "android_chrome_version.py" ]

  sources = [
    lastchange_file,
    template_file,
  ]

  output_file = "$target_gen_dir/chromium_git_revision.h"
  outputs = [ output_file ]

  args = [
    # LASTCHANGE contains "<build hash>-<ref>".  The user agent only wants the
    # "<build hash>" bit, so chop off everything after it.
    "-e",
    "LASTCHANGE=LASTCHANGE[:LASTCHANGE.find('-')]",
    "-f",
    rebase_path(lastchange_file, root_build_dir),
    rebase_path(template_file, root_build_dir),
    rebase_path(output_file, root_build_dir),
  ]
}

group("test_results") {
  data = [
    "//.vpython3",
    "//chromium/build/util/lib/__init__.py",
    "//chromium/build/util/lib/results/",
  ]
}

group("proto") {
  data = [
    "//.vpython3",
    "//chromium/build/util/lib/__init__.py",
    "//chromium/build/util/lib/proto/",
  ]
}