Quelle  Int_Discrete.thy

(*  Title:      HOL/HOLCF/Library/Int_Discrete.thy
  Author: Brian Huffman
*)

section ‹Discrete cpo instance for integers›

theory Int_Discrete
imports HOLCF
begin

text ‹Discrete cpo instance for 🍋‹int›.›

instantiation int :: discrete_cpo
begin

definition below_int_def:
  "(x::int) ⊑ y ⟷ x = y"

instance proof
qed (rule below_int_def)

end

text ‹
  TODO: implement a command to automate discrete predomain instances.
 ›

instantiation int :: predomain
begin

definition
  "(liftemb :: int u → udom u) ≡ liftemb oo u_map⋅(Λ x. Discr x)"

definition
  "(liftprj :: udom u → int u) ≡ u_map⋅(Λ y. undiscr y) oo liftprj"

definition
  "liftdefl ≡ (λ(t::int itself). LIFTDEFL(int discr))"

instance proof
  show "ep_pair liftemb (liftprj :: udom u → int u)"
    unfolding liftemb_int_def liftprj_int_def
    apply (rule ep_pair_comp)
    apply (rule ep_pair_u_map)
    apply (simp add: ep_pair.intro)
    apply (rule predomain_ep)
    done
  show "cast⋅LIFTDEFL(int) = liftemb oo (liftprj :: udom u → int u)"
    unfolding liftemb_int_def liftprj_int_def liftdefl_int_def
    apply (simp add: cast_liftdefl cfcomp1 u_map_map)
    apply (simp add: ID_def [symmetric] u_map_ID)
    done
qed

end

end