Ziele Untersuchung
mit Columbo Integrität von
Datenbanken Interaktion und
Portierbarkeit Ergonomie der
Schnittstellen

Angebot Produkte Projekt Beratung

Mittel Analytik Modellierung Sprachen Algebra Logik Hardware Denken Kreativität

Zusammenhänge Gesellschaft Wirtschaft Branche Firma


products/sources/formale Sprachen/GAP/pkg/ctbllib/doc2/ (Algebra von RWTH Aachen Version 4.15.1^©) Datei vom 25.4.2025 mit Größe 210 kB

SSL chap9_mj.html Sprache: HTML

products/sources/formale Sprachen/GAP/pkg/ctbllib/doc2/chap9_mj.html

<?xml version="1.0" encoding="UTF-8"?>

<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN"
 "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">

<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en">
<head>
<script type="text/javascript"
 src="https://cdn.jsdelivr.net/npm/mathjax@2/MathJax.js?config=TeX-AMS-MML_HTMLorMML">
</script>
<title>GAP (CTblLibXpls) - Chapter 9: Ambiguous Class Fusions in the GAP Character Table Library</title>
<meta http-equiv="content-type" content="text/html; charset=UTF-8" />
<meta name="generator" content="GAPDoc2HTML" />
<link rel="stylesheet" type="text/css" href="manual.css" />
<script src="manual.js" type="text/javascript"></script>
<script type="text/javascript">overwriteStyle();</script>
</head>
<body class="chap9" onload="jscontent()">

<div class="chlinktop">Goto Chapter: <a href="chap0_mj.html">Top</a> <a href="chap1_mj.html">1</a> <a href="chap2_mj.html">2</a> <a href="chap3_mj.html">3</a> <a href="chap4_mj.html">4</a> <a href="chap5_mj.html">5</a> <a href="chap6_mj.html">6</a> <a href="chap7_mj.html">7</a> <a href="chap8_mj.html">8</a> <a href="chap9_mj.html">9</a> <a href="chap10_mj.html">10</a> <a href="chap11_mj.html">11</a> <a href="chapBib_mj.html">Bib</a> <a href="chapInd_mj.html">Ind</a> </div>

<div class="chlinkprevnexttop"> <a href="chap0_mj.html">[Top of Book]</a> <a href="chap0_mj.html#contents">[Contents]</a> <a href="chap8_mj.html">[Previous Chapter]</a> <a href="chap10_mj.html">[Next Chapter]</a> </div>

<a href="chap9.html">[MathJax off]</a>
<a id="X7A03A83E87FB1189" name="X7A03A83E87FB1189"></a>
<div class="ChapSects"><a href="chap9_mj.html#X7A03A83E87FB1189">9 Ambiguous Class Fusions in the GAP Character Table Library</a>
<div class="ContSect"> <a href="chap9_mj.html#X784492877DB04FE9">9.1 Some GAP Utilities</a>

</div>
<div class="ContSect"> <a href="chap9_mj.html#X7EA839057D3AD3B4">9.2 Fusions Determined by Factorization through Intermediate Subgroups</a>

<div class="ContSSBlock">
 <a href="chap9_mj.html#X78DCEEFD85FF1EE2">9.2-1 \(Co_3N5 \rightarrow Co_3\) (September 2002)</a>

 <a href="chap9_mj.html#X86BCEA907EC4C833">9.2-2 \(31:15 \rightarrow B\) (March 2003)</a>

 <a href="chap9_mj.html#X7C719F527831F35A">9.2-3 \(SuzN3 \rightarrow Suz\) (September 2002)</a>

 <a href="chap9_mj.html#X828879F481EF30DD">9.2-4 \(F_{{3+}}N5 \rightarrow F_{{3+}}\) (March 2002)</a>

</div></div>
<div class="ContSect"> <a href="chap9_mj.html#X7981579278F81AC6">9.3 Fusions Determined Using Commutative Diagrams Involving Smaller
Subgroups</a>

<div class="ContSSBlock">
 <a href="chap9_mj.html#X7F5186E28201B027">9.3-1 \(BN7 \rightarrow B\) (March 2002)</a>

 <a href="chap9_mj.html#X79710B137B5BB1B8">9.3-2 \((A_4 \times O_8^+(2).3).2 \rightarrow Fi_{24}^{\prime}\) (November 2002)</a>

 <a href="chap9_mj.html#X85822C647B29117B">9.3-3 \(A_6 \times L_2(8).3 \rightarrow Fi_{24}^{\prime}\) (November 2002)</a>

 <a href="chap9_mj.html#X81A607758682D9A9">9.3-4 \((3^2:D_8 \times U_4(3).2^2).2 \rightarrow B\) (June 2007)</a>

 <a href="chap9_mj.html#X7962DD4387D63675">9.3-5 \(7^{1+4}:(3 \times 2.S_7) \rightarrow M\) (May 2009)</a>

 <a href="chap9_mj.html#X860B6C30812DE3FC">9.3-6 \(3^7.O_7(3):2 \rightarrow Fi_{24}\) (November 2010)</a>

 <a href="chap9_mj.html#X7C3AC42F8342EE2E">9.3-7 \({}^2E_6(2)N3C \rightarrow {}^2E_6(2)\) (January 2019)</a>

</div></div>
<div class="ContSect"> <a href="chap9_mj.html#X84F966E2824F5D52">9.4 Fusions Determined Using Commutative Diagrams Involving Factor
Groups</a>

<div class="ContSSBlock">
 <a href="chap9_mj.html#X7F2B104686509CAA">9.4-1 \(3.A_7 \rightarrow 3.Suz\) (December 2010)</a>

 <a href="chap9_mj.html#X82FB71647D37F4FD">9.4-2 \(S_6 \rightarrow U_4(2)\) (September 2011)</a>

</div></div>
<div class="ContSect"> <a href="chap9_mj.html#X7CFBC41B818A318C">9.5 Fusions Determined Using Commutative Diagrams Involving
Automorphic Extensions</a>

<div class="ContSSBlock">
 <a href="chap9_mj.html#X7E91F8707BA93081">9.5-1 \(U_3(8).3_1 \rightarrow {}^2E_6(2)\) (December 2010)</a>

 <a href="chap9_mj.html#X81B37EF378E89E00">9.5-2 \(L_3(4).2_1 \rightarrow U_6(2)\) (December 2010)</a>

</div></div>
<div class="ContSect"> <a href="chap9_mj.html#X85E2A6F480026C95">9.6 Conditions Imposed by Brauer Tables</a>

<div class="ContSSBlock">
 <a href="chap9_mj.html#X7ACC7F588213D5D5">9.6-1 \(L_2(16).4 \rightarrow J_3.2\) (January 2004)</a>

 <a href="chap9_mj.html#X7ACB86CB82ED49D1">9.6-2 \(L_2(17) \rightarrow S_8(2)\) (July 2004)</a>

 <a href="chap9_mj.html#X7DED4C437D479226">9.6-3 \(L_2(19) \rightarrow J_3\) (April 2003)</a>

</div></div>
<div class="ContSect"> <a href="chap9_mj.html#X8225D9FA80A7D20F">9.7 Fusions Determined by Information about the Groups</a>

<div class="ContSSBlock">
 <a href="chap9_mj.html#X7AE2962E82B4C814">9.7-1 \(U_3(3).2 \rightarrow Fi_{24}^{\prime}\) (November 2002)</a>

 <a href="chap9_mj.html#X83061094871EE241">9.7-2 \(L_2(13).2 \rightarrow Fi_{24}^{\prime}\) (September 2002)</a>

 <a href="chap9_mj.html#X7E9C203C7C4D709D">9.7-3 \(M_{11} \rightarrow B\) (April 2009)</a>

 <a href="chap9_mj.html#X85821D748716DC7E">9.7-4 \(L_2(11):2 \rightarrow B\) (April 2009)</a>

 <a href="chap9_mj.html#X828D81487F57D612">9.7-5 \(L_3(3) \rightarrow B\) (April 2009)</a>

 <a href="chap9_mj.html#X7B4E13337D66020F">9.7-6 \(L_2(17).2 \rightarrow B\) (March 2004)</a>

 <a href="chap9_mj.html#X8528432A84851F7B">9.7-7 \(L_2(49).2_3 \rightarrow B\) (June 2006)</a>

 <a href="chap9_mj.html#X7EAD52AA7A28D956">9.7-8 \(2^3.L_3(2) \rightarrow G_2(5)\) (January 2004)</a>

 <a href="chap9_mj.html#X79617107849A6CEA">9.7-9 \(5^{{1+4}}.2^{{1+4}}.A_5.4 \rightarrow B\) (April 2009)</a>

 <a href="chap9_mj.html#X85C48EEB7B711C09">9.7-10 The fusion from the character table of \(7^2:2L_2(7).2\)
into the table of marks (January 2004)</a>

 <a href="chap9_mj.html#X7B1C689C7EFD07CB">9.7-11 \(3 \times U_4(2) \rightarrow 3_1.U_4(3)\) (March 2010)</a>

 <a href="chap9_mj.html#X7A94F78C792122D5">9.7-12 \(2.3^4.2^3.S_4 \rightarrow 2.A12\) (September 2011)</a>

 <a href="chap9_mj.html#X7E2AF30C7E8F89F9">9.7-13 \(127:7 \rightarrow L_7(2)\) (January 2012)</a>

 <a href="chap9_mj.html#X80051B297DF244CF">9.7-14 \(L_2(59) \rightarrow M\) (May 2009) – Do not use this!</a>

 <a href="chap9_mj.html#X8409DA2E83A41ABE">9.7-15 \(L_2(71) \rightarrow M\) (May 2009)</a>

 <a href="chap9_mj.html#X78B3B1BE7A2CA4D1">9.7-16 \(L_2(41) \rightarrow M\) (April 2012)</a>

</div></div>
</div>

<h3>9 Ambiguous Class Fusions in the GAP Character Table Library</h3>

Date: January 11th, 2004

This is a collection of examples showing how class fusions between character tables can be determined using the GAP system <a href="chapBib_mj.html#biBGAP">[GAP24]</a>. In each of these examples, the fusion is ambiguous in the sense that the character tables do not determine it up to table automorphisms. Our strategy is to compute first all possibilities with the GAP function <code class="func">PossibleClassFusions</code> (<a href="../../../doc/ref/chap73_mj.html#X7883271F7F26356E">Reference: PossibleClassFusions</a>), and then to use either other character tables or information about the groups for excluding some of these candidates until only one (orbit under table automorphisms) remains.

The purpose of this writeup is twofold. On the one hand, the computations are documented this way. On the other hand, the GAP code shown for the examples can be used as test input for automatic checking of the data and the functions used; therefore, each example ends with a comparison of the result with the fusion that is actually stored in the GAP Character Table Library <a href="chapBib_mj.html#biBCTblLib">[Bre25]</a>.

The examples use the GAP Character Table Library, so we first load this package.

<div class="example"><pre>
gap> LoadPackage( "ctbllib", false );
true
</pre></div>

<a id="X784492877DB04FE9" name="X784492877DB04FE9"></a>

<h4>9.1 Some GAP Utilities</h4>

The function <code class="code">SetOfComposedClassFusions</code> takes two list of class fusions, where the first list consists of fusions between the character tables of the groups \(H\) and \(G\), say, and the second list consists of class fusions between the character tables of the groups \(U\) and \(H\), say; the return value is the set of compositions of each map in the first list with each map in the second list (via <code class="func">CompositionMaps</code> (<a href="../../../doc/ref/chap73_mj.html#X8740C1397C6A96C8">Reference: CompositionMaps</a>)).

Note that the returned list may be a proper subset of the set of all possible class fusions between \(U\) and \(G\), which can be computed with <code class="func">PossibleClassFusions</code> (<a href="../../../doc/ref/chap73_mj.html#X7883271F7F26356E">Reference: PossibleClassFusions</a>).

<div class="example"><pre>
gap> SetOfComposedClassFusions:= function( hfusg, ufush )
> local result, map1, map2;
> result:= [];;
> for map2 in hfusg do
> for map1 in ufush do
> AddSet( result, CompositionMaps( map2, map1 ) );
> od;
> od;
> return result;
> end;;
</pre></div>

<a id="X7EA839057D3AD3B4" name="X7EA839057D3AD3B4"></a>

<h4>9.2 Fusions Determined by Factorization through Intermediate Subgroups</h4>

This situation clearly occurs only for nonmaximal subgroups. Interesting examples are Sylow normalizers.

<a id="X78DCEEFD85FF1EE2" name="X78DCEEFD85FF1EE2"></a>

<h5>9.2-1 \(Co_3N5 \rightarrow Co_3\) (September 2002)</h5>

Let \(H\) be the Sylow \(5\) normalizer in the sporadic simple group \(Co_3\). The class fusion of \(H\) into \(Co_3\) is not uniquely determined by the character tables of the two groups.

<div class="example"><pre>
gap> co3:= CharacterTable( "Co3" );
CharacterTable( "Co3" )
gap> h:= CharacterTable( "Co3N5" );
CharacterTable( "5^(1+2):(24:2)" )
gap> hfusco3:= PossibleClassFusions( h, co3 );;
gap> Length( RepresentativesFusions( h, hfusco3, co3 ) );
2
</pre></div>

As \(H\) is not maximal in \(Co_3\), we look at those maximal subgroups of \(Co_3\) whose order is divisible by that of \(H\).

<div class="example"><pre>
gap> mx:= Maxes( co3 );
[ "McL.2", "HS", "U4(3).(2^2)_{133}", "M23", "3^5:(2xm11)",
 "2.S6(2)", "U3(5).3.2", "3^1+4:4s6", "2^4.a8", "L3(4).D12",
 "2xm12", "2^2.[2^7*3^2].S3", "s3xpsl(2,8).3", "a4xs5" ]
gap> maxes:= List( mx, CharacterTable );;
gap> filt:= Filtered( maxes, x -> Size( x ) mod Size( h ) = 0 );
[ CharacterTable( "McL.2" ), CharacterTable( "HS" ),
 CharacterTable( "U3(5).3.2" ) ]
</pre></div>

According to the Atlas (see <a href="chapBib_mj.html#biBCCN85">[CCN+85, pp. 34 and 100]</a>), \(H\) occurs as the Sylow \(5\) normalizer in \(U_3(5).3.2\) and in \(McL.2\); however, \(H\) is not a subgroup of \(HS\), since otherwise \(H\) would be contained in subgroups of type \(U_3(5).2\) (see <a href="chapBib_mj.html#biBCCN85">[CCN+85, p. 80]</a>), but the only possible subgroups in these groups are too small (see <a href="chapBib_mj.html#biBCCN85">[CCN+85, p. 34]</a>).

We compute the possible class fusions from \(H\) into \(McL.2\) and from \(McL.2\) to \(Co_3\), and then form the compositions of these maps.

<div class="example"><pre>
gap> max:= filt[1];;
gap> hfusmax:= PossibleClassFusions( h, max );;
gap> maxfusco3:= PossibleClassFusions( max, co3 );;
gap> comp:= SetOfComposedClassFusions( maxfusco3, hfusmax );;
gap> Length( comp );
2
gap> reps:= RepresentativesFusions( h, comp, co3 );
[ [ 1, 2, 3, 4, 8, 8, 7, 9, 10, 11, 17, 17, 19, 19, 22, 23, 27, 27,
 30, 33, 34, 40, 40, 40, 40, 42 ] ]
</pre></div>

So factoring through a maximal subgroup of type \(McL.2\) determines the fusion from \(H\) to \(Co_3\) uniquely up to table automorphisms.

Alternatively, we can use the group \(U_3(5).3.2\) as intermediate subgroup, which leads to the same result.

<div class="example"><pre>
gap> max:= filt[3];;
gap> hfusmax:= PossibleClassFusions( h, max );;
gap> maxfusco3:= PossibleClassFusions( max, co3 );;
gap> comp:= SetOfComposedClassFusions( maxfusco3, hfusmax );;
gap> reps2:= RepresentativesFusions( h, comp, co3 );;
gap> reps2 = reps;
true
</pre></div>

Finally, we compare the result with the map that is stored on the library table of \(H\).

<div class="example"><pre>
gap> GetFusionMap( h, co3 ) in reps;
true
</pre></div>

<a id="X86BCEA907EC4C833" name="X86BCEA907EC4C833"></a>

<h5>9.2-2 \(31:15 \rightarrow B\) (March 2003)</h5>

The Sylow \(31\) normalizer \(H\) in the sporadic simple group \(B\) has the structure \(31:15\).

<div class="example"><pre>
gap> b:= CharacterTable( "B" );;
gap> h:= CharacterTable( "31:15" );;
gap> hfusb:= PossibleClassFusions( h, b );;
gap> Length( RepresentativesFusions( h, hfusb, b ) );
2
</pre></div>

We determine the correct fusion using the fact that \(H\) is contained in a (maximal) subgroup of type \(Th\) in \(B\).

<div class="example"><pre>
gap> th:= CharacterTable( "Th" );;
gap> hfusth:= PossibleClassFusions( h, th );;
gap> thfusb:= PossibleClassFusions( th, b );;
gap> comp:= SetOfComposedClassFusions( thfusb, hfusth );;
gap> Length( comp );
2
gap> reps:= RepresentativesFusions( h, comp, b );
[ [ 1, 145, 146, 82, 82, 19, 82, 7, 19, 82, 82, 19, 7, 82, 19, 82, 82
 ] ]
gap> GetFusionMap( h, b ) in reps;
true
</pre></div>

<a id="X7C719F527831F35A" name="X7C719F527831F35A"></a>

<h5>9.2-3 \(SuzN3 \rightarrow Suz\) (September 2002)</h5>

The class fusion from the Sylow \(3\) normalizer into the sporadic simple group \(Suz\) is not uniquely determined by the character tables of these groups.

<div class="example"><pre>
gap> h:= CharacterTable( "SuzN3" );
CharacterTable( "3^5:(3^2:SD16)" )
gap> suz:= CharacterTable( "Suz" );
CharacterTable( "Suz" )
gap> hfussuz:= PossibleClassFusions( h, suz );;
gap> Length( RepresentativesFusions( h, hfussuz, suz ) );
2
</pre></div>

Since \(H\) is not maximal in \(Suz\), we try to factorize the fusion through a suitable maximal subgroup.

<div class="example"><pre>
gap> maxes:= List( Maxes( suz ), CharacterTable );;
gap> filt:= Filtered( maxes, x -> Size( x ) mod Size( h ) = 0 );
[ CharacterTable( "3_2.U4(3).2_3'" ), CharacterTable( "3^5:M11" ),
 CharacterTable( "3^2+4:2(2^2xa4)2" ) ]
</pre></div>

The group \(3_2.U_4(3).2_3^{\prime}\) does not admit a fusion from \(H\).

<div class="example"><pre>
gap> PossibleClassFusions( h, filt[1] );
[ ]
</pre></div>

Definitely \(3^5:M_{11}\) contains a group isomorphic with \(H\), because the Sylow \(3\) normalizer in \(M_{11}\) has the structure \(3^2:SD_{16}\); using \(3^{2+4}:2(2^2 \times A_4)2\) would lead to the same result as we get below. We compute the compositions of possible class fusions.

<div class="example"><pre>
gap> max:= filt[2];;
gap> hfusmax:= PossibleClassFusions( h, max );;
gap> maxfussuz:= PossibleClassFusions( max, suz );;
gap> comp:= SetOfComposedClassFusions( maxfussuz, hfusmax );;
gap> repr:= RepresentativesFusions( h, comp, suz );
[ [ 1, 2, 2, 4, 5, 4, 5, 5, 5, 5, 5, 6, 9, 9, 14, 15, 13, 16, 16, 14,
 15, 13, 13, 13, 16, 15, 14, 16, 16, 16, 21, 21, 23, 22, 29, 29,
 29, 38, 39 ] ]
</pre></div>

So the factorization determines the fusion map up to table automorphisms. We check that this map is equal to the stored one.

<div class="example"><pre>
gap> GetFusionMap( h, suz ) in repr;
true
</pre></div>

<a id="X828879F481EF30DD" name="X828879F481EF30DD"></a>

<h5>9.2-4 \(F_{{3+}}N5 \rightarrow F_{{3+}}\) (March 2002)</h5>

The class fusion from the table of the Sylow \(5\) normalizer \(H\) in the sporadic simple group \(F_{{3+}}\) into \(F_{{3+}}\) is ambiguous.

<div class="example"><pre>
gap> f3p:= CharacterTable( "F3+" );;
gap> h:= CharacterTable( "F3+N5" );;
gap> hfusf3p:= PossibleClassFusions( h, f3p );;
gap> Length( RepresentativesFusions( h, hfusf3p, f3p ) );
2
</pre></div>

\(H\) is not maximal in \(F_{{3+}}\), so we look for tables of maximal subgroups that can contain \(H\).

<div class="example"><pre>
gap> maxes:= List( Maxes( f3p ), CharacterTable );;
gap> filt:= Filtered( maxes, x -> Size( x ) mod Size( h ) = 0 );
[ CharacterTable( "Fi23" ), CharacterTable( "2.Fi22.2" ),
 CharacterTable( "(3xO8+(3):3):2" ), CharacterTable( "O10-(2)" ),
 CharacterTable( "(A4xO8+(2).3).2" ), CharacterTable( "He.2" ),
 CharacterTable( "F3+M14" ), CharacterTable( "(A5xA9):2" ) ]
gap> possfus:= List( filt, x -> PossibleClassFusions( h, x ) );
[ [ ], [ ], [ ], [ ],
 [ [ 1, 69, 110, 12, 80, 121, 4, 72, 113, 11, 11, 79, 79, 120, 120,
 3, 71, 11, 79, 23, 91, 112, 120, 132, 29, 32, 97, 100, 37,
 37, 105, 105, 139, 140, 145, 146, 155, 155, 156, 156, 44,
 44, 167, 167, 48, 48, 171, 171, 57, 57, 180, 180, 66, 66,
 189, 189 ],
 [ 1, 69, 110, 12, 80, 121, 4, 72, 113, 11, 11, 79, 79, 120,
 120, 3, 71, 11, 79, 23, 91, 112, 120, 132, 29, 32, 97, 100,
 37, 37, 105, 105, 140, 139, 146, 145, 156, 156, 155, 155,
 44, 44, 167, 167, 48, 48, 171, 171, 57, 57, 180, 180, 66,
 66, 189, 189 ] ], [ ], [ ], [ ] ]
</pre></div>

We see that from the eight possible classes of maximal subgroups in \(F_{{3+}}\) that might contain \(H\), only the group of type \((A_4 \times O_8^+(2).3).2\) admits a class fusion from \(H\). Hence we can compute the compositions of the possible fusions from \(H\) into this group with the possible fusions from this group into \(F_{{3+}}\).

<div class="example"><pre>
gap> max:= filt[5];
CharacterTable( "(A4xO8+(2).3).2" )
gap> hfusmax:= possfus[5];;
gap> maxfusf3p:= PossibleClassFusions( max, f3p );;
gap> comp:= SetOfComposedClassFusions( maxfusf3p, hfusmax );;
gap> Length( comp );
2
gap> repr:= RepresentativesFusions( h, comp, f3p );
[ [ 1, 2, 4, 12, 35, 54, 3, 3, 16, 9, 9, 11, 11, 40, 40, 2, 3, 9, 11,
 35, 36, 13, 40, 90, 7, 22, 19, 20, 43, 43, 50, 50, 8, 8, 23,
 23, 46, 46, 47, 47, 10, 10, 9, 9, 10, 10, 11, 11, 26, 26, 28,
 28, 67, 67, 68, 68 ] ]
</pre></div>

Finally, we check whether the map stored in the table library is correct.

<div class="example"><pre>
gap> GetFusionMap( h, f3p ) in repr;
true
</pre></div>

Note that we did not determine the class fusion from the maximal subgroup \((A_4 \times O_8^+(2).3).2\) into \(F_{{3+}}\) up to table automorphisms (see Section <a href="chap9_mj.html#X79710B137B5BB1B8">9.3-2</a> for this problem), since also the ambiguous result was enough for computing the fusion from \(H\) into \(F_{{3+}}\).

<a id="X7981579278F81AC6" name="X7981579278F81AC6"></a>

<h4>9.3 Fusions Determined Using Commutative Diagrams Involving Smaller
Subgroups</h4>

In each of the following examples, the class fusion of a (not necessarily maximal) subgroup \(M\) of a group \(G\) into \(G\) is determined by considering a proper subgroup \(U\) of \(M\) whose class fusion into \(G\) can be computed, perhaps using another subgroup \(S\) of \(G\) that also contains \(U\).

<center> <img src="ambigfus1.png" alt="setup: some subgroups of G"/> </center>

<a id="X7F5186E28201B027" name="X7F5186E28201B027"></a>

<h5>9.3-1 \(BN7 \rightarrow B\) (March 2002)</h5>

Let \(H\) be a Sylow \(7\) normalizer in the sporadic simple group \(B\). The class fusion of \(H\) into \(B\) is not uniquely determined by the character tables of the two groups.

<div class="example"><pre>
gap> b:= CharacterTable( "B" );
CharacterTable( "B" )
gap> h:= CharacterTable( "BN7" );
CharacterTable( "BN7" )
gap> hfusb:= PossibleClassFusions( h, b );;
gap> Length( RepresentativesFusions( h, hfusb, b ) );
2
</pre></div>

Let us consider a maximal subgroup of the type \(Th\) in \(B\) (cf. <a href="chapBib_mj.html#biBCCN85">[CCN+85, p. 217]</a>). By <a href="chapBib_mj.html#biBCCN85">[CCN+85, p. 177]</a>, the Sylow \(7\) normalizers in \(Th\) are maximal subgroups of \(Th\) and have the structure \(7^2:(3 \times 2S_4)\). Let \(U\) be such a subgroup.

Note that the only maximal subgroups of \(Th\) whose order is divisible by the order of a Sylow \(7\) subgroup of \(B\) have the types \({}^3D_4(2).3\) and \(7^2:(3 \times 2S_4)\), and the Sylow \(7\) normalizers in the former groups have the structure \(7^2:(3 \times 2A_4)\), cf. <a href="chapBib_mj.html#biBCCN85">[CCN+85, p. 89]</a>.

<div class="example"><pre>
gap> Number( Factors( Size( b ) ), x -> x = 7 );
2
gap> th:= CharacterTable( "Th" );
CharacterTable( "Th" )
gap> Filtered( Maxes( th ), x -> Size( CharacterTable( x ) ) mod 7^2 = 0 );
[ "3D4(2).3", "7^2:(3x2S4)" ]
</pre></div>

The class fusion of \(U\) into \(B\) via \(Th\) is uniquely determined by the character tables of these groups.

<div class="example"><pre>
gap> thn7:= CharacterTable( "ThN7" );
CharacterTable( "7^2:(3x2S4)" )
gap> comp:= SetOfComposedClassFusions( PossibleClassFusions( th, b ),
> PossibleClassFusions( thn7, th ) );
[ [ 1, 31, 7, 7, 5, 28, 28, 17, 72, 72, 6, 6, 7, 28, 27, 27, 109,
 109, 17, 45, 45, 72, 72, 127, 127, 127, 127 ] ]
</pre></div>

The condition that the class fusion of \(U\) into \(B\) factors through \(H\) determines the class fusion of \(H\) into \(B\) up to table automorphisms.

<div class="example"><pre>
gap> thn7fush:= PossibleClassFusions( thn7, h );;
gap> filt:= Filtered( hfusb, x ->
> ForAny( thn7fush, y -> CompositionMaps( x, y ) in comp ) );;
gap> Length( RepresentativesFusions( h, filt, b ) );
1
</pre></div>

Finally, we compare the result with the map that is stored on the library table of \(H\).

<div class="example"><pre>
gap> GetFusionMap( h, b ) in filt;
true
</pre></div>

<a id="X79710B137B5BB1B8" name="X79710B137B5BB1B8"></a>

<h5>9.3-2 \((A_4 \times O_8^+(2).3).2 \rightarrow Fi_{24}^{\prime}\) (November 2002)</h5>

The class fusion of the maximal subgroup \(M \cong (A_4 \times O_8^+(2).3).2\) of \(G = Fi_{24}^{\prime}\) is ambiguous.

<div class="example"><pre>
gap> m:= CharacterTable( "(A4xO8+(2).3).2" );;
gap> t:= CharacterTable( "F3+" );;
gap> mfust:= PossibleClassFusions( m, t );;
gap> repr:= RepresentativesFusions( m, mfust, t );;
gap> Length( repr );
2
</pre></div>

We first observe that the elements of order three in the normal subgroup of type \(A_4\) in \(M\) lie in the class <code class="code">3A</code> of \(Fi_{24}^{\prime}\).

<div class="example"><pre>
gap> a4inm:= Filtered( ClassPositionsOfNormalSubgroups( m ),
> n -> Sum( SizesConjugacyClasses( m ){ n } ) = 12 );
[ [ 1, 69, 110 ] ]
gap> OrdersClassRepresentatives( m ){ a4inm[1] };
[ 1, 2, 3 ]
gap> List( repr, map -> map[110] );
[ 4, 4 ]
gap> OrdersClassRepresentatives( t ){ [ 1 .. 4 ] };
[ 1, 2, 2, 3 ]
</pre></div>

Let us take one such element \(g\), say. Its normalizer \(S\) in \(G\) has the structure \((3 \times O_8^+(3).3).2\); this group is maximal in \(G\), and its character table is available in GAP.

<div class="example"><pre>
gap> s:= CharacterTable( "F3+N3A" );
CharacterTable( "(3xO8+(3):3):2" )
</pre></div>

The intersection \(N_M(g) = S \cap M\) contains a subgroup \(U\) of the type \(3 \times O_8^+(2).3\), and in the following we compute the class fusions of \(U\) into \(S\) and \(M\), and then utilize the fact that only those class fusions from \(M\) into \(G\) are possible whose composition with the class fusion from \(U\) into \(M\) equals a composition of class fusions from \(U\) into \(S\) and from \(S\) into \(G\).

<div class="example"><pre>
gap> u:= CharacterTable( "Cyclic", 3 ) * CharacterTable( "O8+(2).3" );
CharacterTable( "C3xO8+(2).3" )
gap> ufuss:= PossibleClassFusions( u, s );;
gap> ufusm:= PossibleClassFusions( u, m );;
gap> sfust:= PossibleClassFusions( s, t );;
gap> comp:= SetOfComposedClassFusions( sfust, ufuss );;
gap> Length( comp );
6
gap> filt:= Filtered( mfust,
> x -> ForAny( ufusm, map -> CompositionMaps( x, map ) in comp ) );;
gap> repr:= RepresentativesFusions( m, filt, t );;
gap> Length( repr );
1
gap> GetFusionMap( m, t ) in repr;
true
</pre></div>

So the class fusion from \(M\) into \(G\) is determined up to table automorphisms by the commutative diagram.

<a id="X85822C647B29117B" name="X85822C647B29117B"></a>

<h5>9.3-3 \(A_6 \times L_2(8).3 \rightarrow Fi_{24}^{\prime}\) (November 2002)</h5>

The class fusion of the maximal subgroup \(M \cong A_6 \times L_2(8).3\) of \(G = Fi_{24}^{\prime}\) is ambiguous.

<div class="example"><pre>
gap> m:= CharacterTable( "A6xL2(8):3" );;
gap> t:= CharacterTable( "F3+" );;
gap> mfust:= PossibleClassFusions( m, t );;
gap> Length( RepresentativesFusions( m, mfust, t ) );
2
</pre></div>

We will use the fact that the direct factor of the type \(A_6\) in \(M\) contains elements in the class <code class="code">3A</code> of \(G\). This fact can be shown as follows.

<div class="example"><pre>
gap> dppos:= ClassPositionsOfDirectProductDecompositions( m );
[ [ [ 1, 12 .. 67 ], [ 1 .. 11 ] ] ]
gap> List( dppos[1], l -> Sum( SizesConjugacyClasses( t ){ l } ) );
[ 17733424133316996808705, 4545066196775803392 ]
gap> List( dppos[1], l -> Sum( SizesConjugacyClasses( m ){ l } ) );
[ 360, 1512 ]
gap> 3Apos:= Position( OrdersClassRepresentatives( t ), 3 );
4
gap> 3Ainm:= List( mfust, map -> Position( map, 3Apos ) );
[ 23, 23, 23, 23, 34, 34, 34, 34 ]
gap> ForAll( 3Ainm, x -> x in dppos[1][1] );
true
</pre></div>

Since the normalizer of an element of order three in \(A_6\) has the form \(3^2:2\), such a <code class="code">3A</code> element in \(M\) contains a subgroup \(U\) of the structure \(3^2:2 \times L_2(8).3\) which is contained in the <code class="code">3A</code> normalizer \(S\) in \(G\), which has the structure \((3 \times O_8^+(3).3).2\).

(Note that all classes in the \(3^2:2\) type group are rational, and its character table is available in the GAP Character Table Library with the identifier <code class="code">"3^2:2"</code>.)

<div class="example"><pre>
gap> u:= CharacterTable( "3^2:2" ) * CharacterTable( "L2(8).3" );
CharacterTable( "3^2:2xL2(8).3" )
gap> s:= CharacterTable( "F3+N3A" );
CharacterTable( "(3xO8+(3):3):2" )
gap> ufuss:= PossibleClassFusions( u, s );;
gap> comp:= SetOfComposedClassFusions( sfust, ufuss );;
gap> ufusm:= PossibleClassFusions( u, m );;
gap> filt:= Filtered( mfust,
> map -> ForAny( ufusm,
> map2 -> CompositionMaps( map, map2 ) in comp ) );;
gap> repr:= RepresentativesFusions( m, filt, t );;
gap> Length( repr );
1
gap> GetFusionMap( m, t ) in repr;
true
</pre></div>

<a id="X81A607758682D9A9" name="X81A607758682D9A9"></a>

<h5>9.3-4 \((3^2:D_8 \times U_4(3).2^2).2 \rightarrow B\) (June 2007)</h5>

Let \(G\) be a maximal subgroup of the type \((3^2:D_8 \times U_4(3).2^2).2\) in the sporadic simple group \(B\), cf. <a href="chapBib_mj.html#biBCCN85">[CCN+85, p. 217]</a>. Computing the class fusion of \(G\) into \(B\) just from the character tables of the two groups takes extremely long. So we use additional information.

According to <a href="chapBib_mj.html#biBCCN85">[CCN+85, p. 217]</a>, \(G\) is the normalizer in \(B\) of an elementary abelian group \(\langle x, y \rangle\) of order \(9\), with \(x, y\) in the class <code class="code">3A</code> of \(B\), and \(N = N_B(\langle x \rangle)\) has the structure \(S_3 \times Fi_{22}.2\). The intersection \(G \cap N\) has the structure \(S_3 \times S_3 \times U_4(3).2^2\), which is the direct product of \(S_3\) and the normalizer in \(Fi_{22}.2\) of a <code class="code">3A</code> element of \(Fi_{22}.2\), see <a href="chapBib_mj.html#biBCCN85">[CCN+85, p. 163]</a>. Thus we may use that the class fusions from \(G \cap N\) into \(B\) through \(G\) or \(N\) coincide.

The class fusion from \(N\) into \(B\) is uniquely determined by the character tables.

<div class="example"><pre>
gap> b:= CharacterTable( "B" );;
gap> n:= CharacterTable( "BN3A" );
CharacterTable( "S3xFi22.2" )
gap> nfusb:= PossibleClassFusions( n, b );;
gap> Length( nfusb );
1
gap> nfusb:= nfusb[1];;
</pre></div>

The computation of the class fusion from \(G \cap N\) into \(N\) is sped up by computing first the class fusion modulo the direct factor \(S_3\), and then lifting these fusion maps.

<div class="example"><pre>
gap> fi222:= CharacterTable( "Fi22.2" );;
gap> fi222n3a:= CharacterTable( "S3xU4(3).(2^2)_{122}" );;
gap> s3:= CharacterTable( "S3" );;
gap> inter:= s3 * fi222n3a;;
gap> intermods3fusnmods3:= PossibleClassFusions( fi222n3a, fi222 );;
gap> Length( intermods3fusnmods3 );
2
gap> Length( RepresentativesFusions( fi222n3a, intermods3fusnmods3, fi222 ) );
1
</pre></div>

We get two equivalent possibilities, and need to consider only one of them. For lifting it to a map between \(G \cap N\) and \(N\), the safe way is to use the fusion map between the two factors for computing an approximation. (Additionally, we could interpret the known maps as fusions between two subgroups, and use this for improving the approximation, but in this case the speedup is not worth the effort.)

<div class="example"><pre>
gap> interfusn:= CompositionMaps( InverseMap( GetFusionMap( n, fi222 ) ),
> CompositionMaps( intermods3fusnmods3[1],
> GetFusionMap( inter, fi222n3a ) ) );;
gap> interfusn:= PossibleClassFusions( inter, n,
> rec( fusionmap:= interfusn, quick:= true ) );;
gap> Length( interfusn );
1
</pre></div>

The lift is unique. Since we lift a class fusion to direct products, we could also <q>extend</q> the fusion directly. But note that this would assume the ordering of classes in character tables of direct products. This alternative would work as follows.

<div class="example"><pre>
gap> nccl:= NrConjugacyClasses( fi222 );;
gap> interfusn[1] = Concatenation( List( [ 0 .. 2 ],
> i -> intermods3fusnmods3[1] + i * nccl ) );
true
</pre></div>

Next we compute the class fusions from \(G \cap N\) to \(G\). We get two equivalent solutions.

<div class="example"><pre>
gap> tblg:= CharacterTable( "BM14" );
CharacterTable( "(3^2:D8xU4(3).2^2).2" )
gap> interfusg:= PossibleClassFusions( inter, tblg );;
gap> Length( interfusg );
2
gap> Length( RepresentativesFusions( inter, interfusg, tblg ) );
1
</pre></div>

The approximation of the class fusion from \(G\) to \(B\) is computed by composing the known maps. Because we have chosen one of the two possible maps from \(G \cap N\) to \(N\), here we consider the two possibilities. From these approximations, we compute the possible class fusions.

<div class="example"><pre>
gap> interfusb:= CompositionMaps( nfusb, interfusn[1] );;
gap> approx:= List( interfusg,
> map -> CompositionMaps( interfusb, InverseMap( map ) ) );;
gap> gfusb:= Set( Concatenation( List( approx,
> map -> PossibleClassFusions( tblg, b,
> rec( fusionmap:= map ) ) ) ) );;
gap> Length( gfusb );
4
gap> Length( RepresentativesFusions( tblg, gfusb, b ) );
1
</pre></div>

Finally, we compare the result with the class fusion that is stored on the library table.

<div class="example"><pre>
gap> GetFusionMap( tblg, b ) in gfusb;
true
</pre></div>

<a id="X7962DD4387D63675" name="X7962DD4387D63675"></a>

<h5>9.3-5 \(7^{1+4}:(3 \times 2.S_7) \rightarrow M\) (May 2009)</h5>

The class fusion of the maximal subgroup \(U\) of type \(7^{1+4}:(3 \times 2.S_7)\) of the Monster group \(M\) into \(M\) is ambiguous.

<div class="example"><pre>
gap> tblu:= CharacterTable( "7^(1+4):(3x2.S7)" );;
gap> m:= CharacterTable( "M" );;
gap> ufusm:= PossibleClassFusions( tblu, m );;
gap> Length( RepresentativesFusions( tblu, ufusm, m ) );
2
</pre></div>

The subgroup \(U\) contains a Sylow \(7\)-subgroup of \(M\), and the only maximal subgroups of \(M\) with this property are the class of \(U\) and another class of subgroups, of the type \(7^{2+1+2}:GL_2(7)\). Moreover, it turns out that the Sylow \(7\) normalizers in the subgroups in both classes have the same order, hence they are the Sylow \(7\) normalizers in \(M\).

For that, we use representations from the Atlas of Group Representations <a href="chapBib_mj.html#biBAGRv3">[WWT+]</a>, and access these representations via the GAP package AtlasRep (<a href="chapBib_mj.html#biBAtlasRep">[WPN+22]</a>).

<div class="example"><pre>
gap> LoadPackage( "atlasrep", false );
true
gap> g1:= AtlasGroup( "7^(2+1+2):GL2(7)" );;
gap> s1:= SylowSubgroup( g1, 7 );;
gap> n1:= Normalizer( g1, s1 );;
gap> g2:= AtlasGroup( "7^(1+4):(3x2.S7)" );;
gap> s2:= SylowSubgroup( g2, 7 );;
gap> n2:= Normalizer( g2, s2 );;
gap> Size( n1 ) = Size( n2 );
true
gap> ( Size( m ) / Size( s1 ) ) mod 7 <> 0;
true
</pre></div>

So let \(N\) be a Sylow \(7\) normalizer in \(U\), and choose a subgroup \(S\) of the type \(7^{2+1+2}:GL_2(7)\) that contains \(N\).

We compute the character table of \(N\). Computing the possible class fusions of \(N\) into \(M\) directly yields two possibilities, but the class fusion of \(N\) into \(M\) via \(S\) is uniquely determined by the character tables.

<div class="example"><pre>
gap> tbln:= CharacterTable( Image( IsomorphismPcGroup( n1 ) ) );;
gap> tbls:= CharacterTable( "7^(2+1+2):GL2(7)" );;
gap> nfusm:= PossibleClassFusions( tbln, m );;
gap> Length( RepresentativesFusions( tbln, nfusm, m ) );
2
gap> nfuss:= PossibleClassFusions( tbln, tbls );;
gap> sfusm:= PossibleClassFusions( tbls, m );;
gap> nfusm:= SetOfComposedClassFusions( sfusm, nfuss );;
gap> Length( nfusm );
1
</pre></div>

Now we use the condition that the class fusions from \(N\) into \(M\) factors through \(U\). This determines the class fusion of \(U\) into \(M\) up to table automorphisms.

<div class="example"><pre>
gap> nfusu:= PossibleClassFusions( tbln, tblu );;
gap> ufusm:= Filtered( ufusm, map2 -> ForAny( nfusu, 
> map1 -> CompositionMaps( map2, map1 ) in nfusm ) );;
gap> Length( RepresentativesFusions( tblu, ufusm, m ) );
1
</pre></div>

Let \(C\) be the centralizer in \(U\) of the normal subgroup of order \(7\); note that \(C\) is the <code class="code">7B</code> centralizer on \(M\). We can use the information about the class fusion of \(U\) into \(M\) for determining the class fusion of \(C\) into \(M\). The class fusion of \(C\) into \(M\) is not determined by the character tables, but the class fusion of \(C\) into \(U\) is determined up to table automorphisms, so the same holds for the class fusion of \(C\) into \(M\).

<div class="example"><pre>
gap> tblc:= CharacterTable( "MC7B" ); 
CharacterTable( "7^1+4.2A7" )
gap> cfusm:= PossibleClassFusions( tblc, m );; 
gap> Length( RepresentativesFusions( tblc, cfusm, m ) );
2
gap> cfusu:= PossibleClassFusions( tblc, tblu );;
gap> cfusm:= SetOfComposedClassFusions( ufusm, cfusu );;
gap> Length( RepresentativesFusions( tblc, cfusm, m ) );
1
</pre></div>

<a id="X860B6C30812DE3FC" name="X860B6C30812DE3FC"></a>

<h5>9.3-6 \(3^7.O_7(3):2 \rightarrow Fi_{24}\) (November 2010)</h5>

The class fusion of the maximal subgroup \(M \cong 3^7.O_7(3):2\) of \(G = Fi_{24} = F_{{3+}}.2\) is ambiguous.

<div class="example"><pre>
gap> m:= CharacterTable( "3^7.O7(3):2" );;
gap> t:= CharacterTable( "F3+.2" );;
gap> mfust:= PossibleClassFusions( m, t );;
gap> Length( RepresentativesFusions( m, mfust, t ) );
2
</pre></div>

We will use the fact that the elementary abelian normal subgroup of order \(3^7\) in \(M\) contains an element \(x\), say, in the class <code class="code">3A</code> of \(G\). This fact can be shown as follows.

<div class="example"><pre>
gap> nsg:= ClassPositionsOfNormalSubgroups( m );
[ [ 1 ], [ 1 .. 4 ], [ 1 .. 158 ], [ 1 .. 291 ] ]
gap> Sum( SizesConjugacyClasses( m ){ nsg[2] } );
2187
gap> 3^7;
2187
gap> rest:= Set( mfust, map -> map{ nsg[2] } );
[ [ 1, 4, 5, 6 ] ]
gap> List( rest, l -> ClassNames( t, "Atlas" ){ l } );
[ [ "1A", "3A", "3B", "3C" ] ]
</pre></div>

The normalizer \(S\) of \(\langle x \rangle\) in \(G\) has the form \(S_3 \times O_8^+(3):S_3\), and the order of \(U = S \cap M = N_M( \langle x \rangle)\) is \(53059069440\), so \(U\) has index \(3360\) in \(S\).

<div class="example"><pre>
gap> s:= CharacterTable( "F3+.2N3A" );
CharacterTable( "S3xO8+(3):S3" )
gap> PowerMap( m, 2 )[4];
4
gap> size_u:= 2 * SizesCentralizers( m )[ 2 ];
53059069440
gap> Size( s ) / size_u;
3360
</pre></div>

Using the list of maximal subgroups of \(O_8^+(3)\), we see that only the maximal subgroups of the type \(3^6:L_4(3)\) have index dividing \(3360\) in \(O_8^+(3)\). (There are three classes of such subgroups.) This implies that \(U\) contains a subgroup of the type \(S_3 \times 3^6:L_4(3)\).

<div class="example"><pre>
gap> o8p3:= CharacterTable( "O8+(3)" );;
gap> mx:= List( Maxes( o8p3 ), CharacterTable );;
gap> filt:= Filtered( mx, x -> 3360 mod Index( o8p3, x ) = 0 );
[ CharacterTable( "3^6:L4(3)" ), CharacterTable( "O8+(3)M8" ),
 CharacterTable( "O8+(3)M9" ) ]
gap> List( filt, x -> Index( o8p3, x ) );
[ 1120, 1120, 1120 ]
</pre></div>

--> --------------------

--> maximum size reached

--> --------------------

quality95%

¤ Die Informationen auf dieser Webseite wurden nach bestem Wissen sorgfältig zusammengestellt. Es wird jedoch weder Vollständigkeit, noch Richtigkeit, noch Qualität der bereit gestellten Informationen zugesichert.0.35Bemerkung: (vorverarbeitet) ¤

Wurzel

Suchen

Beweissystem der NASA

Beweissystem Isabelle

NIST Cobol Testsuite

Cephes Mathematical Library

Wiener Entwicklungsmethode

Haftungshinweis

Die Informationen auf dieser Webseite wurden nach bestem Wissen sorgfältig zusammengestellt. Es wird jedoch weder Vollständigkeit, noch Richtigkeit, noch Qualität der bereit gestellten Informationen zugesichert.